home *** CD-ROM | disk | FTP | other *** search
/ Power Programmierung / Power-Programmierung (Tewi)(1994).iso / assemblr / library / sampler0 / snoop.asm < prev    next >
Assembly Source File  |  1987-05-20  |  94KB  |  2,513 lines
  1. ; snoop.asm
  2. ;
  3. ; Written By Ray Smith
  4. ; Bix Name: rjsmith
  5. ; Copyright (c) 1987, Smith, Brittain & Associates. All rights reserved.
  6. ;
  7. ;
  8. ;*****************************************************************************
  9. ; Usage: snoop [/d] [/e] [/i] [/m] [/a] [/x] [/n]
  10. ;
  11. ;        where d = resident and installed device drivers
  12. ;              e = system equipment and configuration
  13. ;              i = Invars Table
  14. ;              m = Memory Control Blocks
  15. ;              a = all of the above
  16. ;              x = all of the above except /e
  17. ;              n = do Not pause the display, allowing the output to be 
  18. ;                  redirected to a file in a continuous stream.
  19. ;
  20. ;*****************************************************************************
  21. ; 
  22. ;
  23. .8087
  24. cseg    segment para public 'code'
  25.     org     100h                     ; this will be a .com file
  26.     assume cs:cseg,ds:cseg           ; all seg regs point to start of PSP
  27. main    proc far
  28. ;
  29. begin:    jmp    entry                     ; go around the data
  30. ;
  31. ;***********************************************************************
  32. ;* Explanation of bit settings in byte "config_flag"
  33. ;***********************************************************************
  34. ;    
  35. ; Value      8   4   2   1     8   4   2   1
  36. ;        +-----------------+-----------------+
  37. ;  Bit   |                 |                 |
  38. ; Number |  07  06  05  04 |  03  02  01  00 |
  39. ;        |                 |                 |
  40. ;        +-----------------+----------------------------------------+
  41. ;     01 |   |   |   |   |     |   |   |   1 = PC/AT Class Machine  |
  42. ;     02 |   |   |   |   |     |   |   1 = Enhanced BIOS Present    |         
  43. ;     04 |   |   |   |   |     |   1 = Enhanced Keyboard Attached   |     
  44. ;     08 |   |   |   |   |     1 = Compaq DeskPro 386 or klone      | 
  45. ;     10 |   |   |   |   1 = PC/XT Class Machine                    | 
  46. ;     20 |   |   |   1 = PC Class Machine                           |
  47. ;     40 |   |   1 = PC Convertible                                 |
  48. ;     80 |   1 = PC/XT 089                                          |
  49. ;        +----------------------------------------------------------+
  50. ;
  51. ;
  52. display_flag db 0h
  53. config_flag  db 0h
  54. equ_flag     db 0h
  55. inv_flag     db 0h
  56. drv_flag     db 0h
  57. pse_flag     db 0h
  58. mem_flag     db 0h
  59. cpu_flag     db 0h
  60. ps2_flag     db 0h
  61. sys_flag     db 0h
  62. env_flag     db 0h
  63. psp_flag     db 0h
  64. tsr_flag     db 0h
  65. mt_flag      db 0h
  66. data_flag    db 0h
  67. switchar     db 2Fh   ; "/" for command line switches
  68. pathchar     db 5Ch   ; "\" for path name delimiter
  69. switch_err   db 0h 
  70. scan_code    db 44h    
  71. loop_count   dw 0h
  72. arg_cnt      dw 0h
  73. argc         db 0h
  74. optcnt       db 0h
  75. portcnt      db 0h
  76. total_pages  dw 0h
  77. avail_pages  dw 0h
  78. firstenv     db 01h
  79. firstpsp     db 01h
  80. firstmcb     db 01h
  81. firstsys     db 01h
  82. one          db 01h
  83. linecnt      db 0h
  84. de_allocmsg  db 'Deallocated$'  
  85. systype      db 'DOS $'
  86. psptype      db 'PSP $'
  87. envtype      db 'ENV $'
  88. datatype     db 'DATA$'
  89. mttype       db 'Unkn$'
  90. lastdpb      db 'Chain Ends$'
  91. notread      db 'nr$'     ; drive was not read
  92. dos_vers     dw 0h
  93. emm_vers     db 0h
  94. rom_flag db     0FFh
  95. get_key  db     0h        ; default BIOS Int 16h function to read a key
  96. avail_c  db     01h       ; default BIOS Int 16h function to check avail char
  97. get_sts  db     02h       ; default BIOS Int 16h function to check shift status
  98. control  dw     0h        ; save 80x87 control word
  99. sav_code db     0h
  100. sav_addr dw     0h
  101. sav_off  dw     0h
  102. invar_seg dw    0h
  103. invar_off dw    0h
  104. dpb_seg  dw     0h
  105. dpb_off  dw     0h
  106. sav_name db     '             '
  107.          db     '$'
  108. type_drv dw     0h
  109. devh_seg dw     0h        ; segment address NUL device driver
  110. devh_off dw     0h        ; offset  address NUL device driver
  111. next_seg dw     0h        ; next seg addr
  112. next_off dw     0h        ; next off addr
  113. colon    db     ':'
  114. emm_name db     'EMMXXXX0' ; Guaranteed emm device driver file name
  115. blank    db     20h
  116. ourcopy  db     0Dh,0Ah,' Copyright (c) 1987 Smith, Brittain & Associates. '
  117.          db     'All Rights Reserved.$'
  118. mcbseg   dw     0h
  119. filename db '        $'
  120. dataname db '        $'
  121.          db     'Written By Raymond J. Smith'
  122. msg1     db    0Dh,0Ah,' Machine is an IBM PC/AT or AT klone $'
  123. msg1A     db    0Dh,0Ah,' Machine is an IBM PC/AT Model 339   $'
  124. msg1B     db    0Dh,0Ah,' Machine is an IBM PC/AT Model 239   $'
  125. msg1C     db    0Dh,0Ah,' Machine is an IBM PC/AT Model 099   $'
  126. msg1D     db    0Dh,0Ah,' Machine is a Compaq Dekspro 386 or compatible$'
  127. msg1E     db    0Dh,0Ah,' Machine is an IBM Personal System/2 Model 30$'
  128. msg1F     db    0Dh,0Ah,' Machine is an IBM Personal System/2 Model 50$'
  129. msg1G     db    0Dh,0Ah,' Machine is an IBM Personal System/2 Model 60$'
  130. msg1H     db    0Dh,0Ah,' Machine is an IBM Personal System/2 Model 80$'
  131. msg2     db    0Dh,0Ah,'         Enhanced BIOS is present $'
  132. msg3     db    0Dh,0Ah,'         Enhanced Keyboard is attached  $'
  133. msg4     db    0Dh,0Ah,' Machine ID byte contains code ==> $'
  134. msg5     db    0Dh,0Ah,'         No Enhanced BIOS is present $'
  135. msg6     db    0Dh,0Ah,'         No Enhanced Keyboard is attached  $'
  136. msg7     db    0Dh,0Ah,'                           Press any key to continue... $'
  137. msg9     db    0Dh,0Ah,'         EGA is active adapter $'
  138. msg10     db    0Dh,0Ah,'         EGA is active and is monochrome $'
  139. msg11     db    0Dh,0Ah,'         EGA is not active, a MDA or Hercules card is active $'
  140. msg12     db    0Dh,0Ah,'         EGA is not active, a CGA is active $'
  141. msg14    db    0Dh,0Ah,'         EGA has 64kb graphics memory installed  $'
  142. msg15    db    0Dh,0Ah,'         EGA has 128kb graphics memory installed  $'
  143. msg16    db    0Dh,0Ah,'         EGA has 192kb graphics memory installed  $'
  144. msg17    db    0Dh,0Ah,'         EGA has 256kb graphics memory installed  $'
  145. msg18    db    0Dh,0Ah,'         Enhanced Color Display is attached $'
  146. msg18A   db    0Dh,0Ah,'         Enhanced Color Display in Color Graphics mode is attached $'
  147. msg19    db    0Dh,0Ah,'         Normal Color Display is attached $'
  148. msg19A   db    0Dh,0Ah,'         CGA is active$'
  149. msg20    db    0Dh,0Ah,'         Monochrome Display is active$'
  150. msg21     db    0Dh,0Ah,' Machine is an IBM PC/XT or XT klone $'
  151. msg22     db    0Dh,0Ah,' Machine is an IBM PC or PC klone $'
  152. msg23     db    0Dh,0Ah,' Machine is an IBM PC convertible $'
  153. msg24     db    0Dh,0Ah,' Machine is a PC/XT Model 089 $'
  154. msg25     db    0Dh,0Ah,' Machine is a PC/XT Model 286 $'    
  155. msg26     db    0Dh,0Ah,'         EGA switches improperly set $'
  156. msg27    db    0Dh,0Ah,'         8087 is installed $'
  157. msg28    db    0Dh,0Ah,'         80287 is installed $'
  158. msg29    db    0Dh,0Ah,'         no NDP is installed$'
  159. msg30    db    ' exTEnded memory installed$',0Dh,0Ah
  160. msg31    db    ' exPAnded memory installed$'
  161. msg31A   db     ' total EMS pages$'
  162. msg31B   db     ' available EMS pages$'
  163. msg31C   db     0Dh,0Ah,'         EMM Version: $'
  164. msg32    db    0Dh,0Ah,'         no$'
  165. msg33    db    0Dh,0Ah,'         System is operating under DOS Version $'
  166. msg33A   db     0Dh,0Ah,'         Switch character currently in effect is $'
  167. msg33B   db     0Dh,0Ah,'         DOS Int 21h Function 37h not responding$'
  168. msg34    db    ' is installed$'
  169. msg35    db    '3.00$'
  170. msg36    db    '3.10$'
  171. msg37    db    '3.20$'
  172. msg37A   db    '3.30$'
  173. msg37B   db    '3.40$'
  174. msg38    db    '2.00$'
  175. msg39    db    '2.10$'
  176. msg40    db    'is unknown$'
  177. msg41    db    'kb$'
  178. msg42    db    ' base memory installed$',0Dh,0Ah
  179. msg43    db    ' OR the EMM is not installed$'
  180. msg44    db    'LPT1: $'
  181. msg45    db    'LPT2: $'
  182. msg46    db    'LPT3: $'
  183. msg47    db    'COM1: $'
  184. msg48    db    'COM2: $'
  185. msg48A   db    'COM3: $'
  186. msg48B   db    'COM4: $'
  187. msg49    db    'No Parallel Ports active$'
  188. msg50    db    'No Serial Ports active$'
  189. msg98    db    '2.x$'
  190. msg99    db    '3.x$'
  191. copyrite db     'ROM BIOS Copyright ==> $'
  192. biosdate db     'ROM BIOS dated $'
  193. egacopy  db     'EGA BIOS Copyright ==> $'
  194. egadate  db     'EGA BIOS dated $'
  195. baddrv   db    'Corrupted EMM Driver $'
  196. badbrd   db    'Malfunction in exPAnded memory hardware$'
  197. romid    db    'Adapter ROM signature found at segment $'
  198. noroms   db    'No adapter ROMs detected $'
  199. newline  db    0Dh,0Ah,'$'
  200. indent   db     '         $'
  201. rom_sig  dw     0AA55h
  202. tbuff    db     255 dup('$')
  203. char_dev db     'Char   $'
  204. blk_dev  db     'Block  $'
  205. clk_dev  db     'Clock  $'
  206. cmndmsg  db     'COMMAND $'
  207. sysmsg   db     'System  $'
  208. freemsg  db     'Free    $'
  209. mtblkmsg db     '<Empty> $'
  210. unknmsg  db     'Unknown $'
  211. envmsg   db     'Process Env  $'
  212. mastenv  db     'Master Env   $'
  213. tsrmsg   db     'TSR          $'
  214. resdmsg  db     'Resident part$'
  215. datamsg  db     'Process Data $'
  216. thismsg  db     'Transient    $'
  217. drvmsg   db     'Dev Drvs, etc$'
  218. space1   db     ' $'
  219. space2   db     '  $'
  220. space3   db     '   $'
  221. space4   db     '    $'   
  222. space5   db     '     $'
  223. space6   db     '      $'
  224. space7   db     '       $'
  225. space8   db     '        $'
  226. space9   db     '         $'
  227. space10  db     '          $'
  228. space11  db     '           $'
  229. space12  db     '            $'
  230. space13  db     '             $'
  231. space14  db     '              $'
  232. scr1     db 0Dh,0Ah,'                     Partial Contents of DOS "Invar" Table'
  233.          db 0Dh,0Ah,' '  
  234.          db 0Dh,0Ah,'   Invar        First      1st Dir      Size of    Drive/Directory  DOS "Busy"'
  235.          db 0Dh,0Ah,'   Table      DPB Table     Buffer      1 Cache         Table         Flag'
  236.          db 0Dh,0Ah,' Seg : Off    Seg : Off    Seg : Off    Buffer        Seg : Off     Seg : Off'
  237.          db 0Dh,0Ah,' ---------    ---------    ---------    -------       ---------     --------- $'
  238. scr1A    db 0Dh,0Ah,'                     Contents of DPB Table By Drive'
  239.      db 0Dh,0Ah,'                                                        Dev Drvr      Next DPB'
  240.      db 0Dh,0Ah,'Drv DU BPC  SPC   RS  CF  MDE   FUS   TCC   SIF  FDS    Hdr Addr  MD   Address'
  241.      db 0Dh,0Ah,'--  -- ---- ---  ---- --  ----  ----  ----  ---  ----  ---------  --  ---------$'
  242. scr2     db 0Dh,0Ah,'                       Installed Device Drivers'
  243.          db 0Dh,0Ah,'       Name or      Header Address   Entry Points               DOS'
  244.          db 0Dh,0Ah,'Type   # Units        Seg : Off      Strat  Interpt   Attrib  Version'
  245.          db 0Dh,0Ah,'----------------------------------------------------------------------------$'
  246. scr3     db 0Dh,0Ah,'                             Memory  Allocation '
  247.          db 0Dh,0Ah,' '  
  248.          db 0Dh,0Ah,'MCB   Points Paras                                         Hooked'
  249.          db 0Dh,0Ah,'Addr  To Blk Alloc Type Owner     Comment       Cmnd Line  Vectors'
  250.          db 0Dh,0Ah,'----  ----   ----  ---- --------  -----------   ---------  -------------------$'
  251. cnt      dw 00h
  252. vectcnt  dw 00h
  253. blk_beg  dw 00h
  254. blk_end  dw 00h
  255. usemsg   db 0Dh,0Ah,' Usage: snoop [/d] [/e] [/i] [/m] [/a] [/n]',0Dh,0Ah
  256.          db 0Dh,0Ah
  257.          db 0Dh,0Ah,'        where d = list device drivers'
  258.          db 0Dh,0Ah,'              e = list equipment'
  259.          db 0Dh,0Ah,'              i = list Invars Table and DPBs'
  260.          db 0Dh,0Ah,'              m = list Memory Control Blocks'
  261.          db 0Dh,0Ah,'              a = list all of the above'
  262.          db 0Dh,0Ah,'              n = do Not pause the display'
  263.          db 0Dh,0Ah,'              x = list all of the above except e'
  264.          db 0Dh,0Ah,'                  (for non-IBM BIOS compatible machines)$'
  265. ;
  266. ;***********************************************************************
  267. ;* Beginning of Code Seg
  268. ;***********************************************************************
  269. entry:
  270.         call switch_char                 ; go see what they're using for paths
  271.         mov  switch_err,al               ; check for error and store for later 
  272.         call chk_switch                  ; get our command line switches
  273.         mov  ah,30h             ; get dos ver num
  274.     int  21h             ; go do it
  275.            xchg ah,al             ; turn it around
  276.         mov  dos_vers,ax                 ; need for NUL device driver location
  277.     cmp  ax,0200h                 ; 2.00 or greater?
  278.     jae  oz_ok
  279. bad_oz:
  280.     jmp  quit                        ; need 2.0 or greater
  281. oz_ok:
  282.     mov  dx,offset ourcopy         ; display our copyright message
  283.         call dostty
  284.     mov  dx,offset newline         
  285.         call dostty
  286.         cmp  equ_flag,0FFh               ; switch set for equipment list?
  287.         je   equip_tests                 ; yes
  288.         jmp  invar_chk                   ; no - bypass equipment list
  289.  
  290. equip_tests:
  291.         clc                              ; clear the carry flag for error rtn
  292.         mov  ah,0C0h                     ; get configuration parameters
  293.         int  15h                         ; avaialable on AT class machines only
  294.         sti                              ; int 15h does not reenable interrupts
  295.         jc   is_old                      ; it's a PC
  296.         cmp  ah,80h                      ; return value if original PC
  297.         je   is_old                      ; 86h is returned on all PS/2 models
  298.         cmp  ah,86h                      ; return value if not new machine
  299.         jne  is_new                      ; 86h is returned on all PS/2 models
  300. is_old:
  301.         jmp  test_more                   ; it's either a PS/2 or PC PC/XT class
  302. is_new:                                  ; determine machine type
  303.         cmp  ax,00FFh                    ; return value if  PS/2
  304.         jne  not_new_mod                 ; 
  305.         call chk_ps2
  306.         cmp  ps2_flag,0h
  307.         je   not_new_mod                 ; 
  308.         jmp  at_tests
  309. not_new_mod:
  310.         cmp  byte ptr es:[bx+2],0FCh     ; AT class machine ID
  311.         je   chk_339
  312.         jmp  test_more  
  313.  
  314. chk_339:
  315.         cmp  byte ptr es:[bx+3],01h      ; check sub-model type byte
  316.         je   is_339                      ; 1 means IBM AT/339 or Compaq 386
  317.         cmp  byte ptr es:[bx+3],02h      ; check sub-model type byte
  318.         jne  next_one
  319.         jmp  xt_286                      ; a 2 means it's an IBM XT/286
  320. next_one:
  321.         cmp  byte ptr es:[bx+3],0h       ; check sub-model type byte
  322.         je   is_239                      ; 0 means it's an IBM AT/239 or 099
  323.         jmp  test_more                   ; (note:AT/239 has rom 06/10/85)
  324.  
  325. is_339:                                  ; mach id byte is FCh - means little
  326.         call chk_cpu                     ; see if 386 or 286 cpu
  327.     cmp  byte ptr cs:cpu_flag,03h    ; is it a 386 cpu?
  328.         je   is_386                      ; 
  329. is_286:                                  ; it's a 286 cpu
  330.     or   byte ptr cs:config_flag,01h ; indicate PC/AT
  331.     mov  dx,offset msg1A         ; AT class message
  332.         call dostty
  333.         jmp  at_tests
  334. is_386:
  335.     or   byte ptr cs:config_flag,09h ; indicate PC/AT class & 386 class
  336.     mov  dx,offset msg1D         ; Compaq DeskPro 386 Class message
  337.         call dostty
  338.         jmp  at_tests
  339.  
  340. is_239:
  341.     or   byte ptr cs:config_flag,01h ; indicate PC/AT
  342.         cmp  byte ptr es:[bx+4],0h       ; check bios level byte
  343.         je   is_099                      ; 0 means it's an IBM AT/099
  344.         cmp  byte ptr es:[bx+4],01       ; check bios level byte
  345.         jne  test_more                   ; 1 means it's an IBM AT/239
  346.     mov  dx,offset msg1B         ; Einen Klonen Machinen message
  347.         call dostty                      ; if all tests fail, assume klone
  348.         jmp  at_tests                    ; test for AT type stuff
  349. is_099:
  350.     mov  dx,offset msg1C         ; original 6 mHz AT
  351.         call dostty
  352.         jmp  at_tests
  353.  
  354. ;***********************************************************************
  355. ;* Determine Machine Type for non_AT type machines.                    *
  356. ;***********************************************************************
  357. test_more:        
  358.     mov  ax,0F000h                 ; seg address of rom bios
  359.     mov  es,ax                       ; establish addressibility
  360.     mov  ax,word ptr es:[0FFFEh]     ; offset of rom bios machine id byte
  361.         call chk_mod30                   ; see if PS/2 Model 30 first 
  362.         cmp  ps2_flag,30h                ; is it a PS/2 model 30?
  363.         jne  not_a_30                    ; if greater, is model 50/60/80
  364.         jmp  chk_mem
  365. not_a_30:
  366.     cmp  al,0FCh                   ; not PS/2: PC/AT? Compaq 386? XT/286?
  367.         je   at_ok                          ; 
  368.     jmp  not_at             ; it's not PS/2 or AT class
  369. at_ok:
  370.     or   byte ptr cs:config_flag,01h ; indicate PC/AT
  371.     mov  dx,offset msg1         ; 
  372.         call dostty
  373.         jmp  at_tests
  374.  
  375. xt_286:
  376.     or   byte ptr cs:config_flag,01h ; indicate PC/AT class machine
  377.     mov  dx,offset msg25         ; 
  378.         call dostty
  379.  
  380. ;***********************************************************************
  381. ;* These tests are applicable to AT class machines only.               *
  382. ;***********************************************************************
  383. ;
  384. at_tests:
  385.                                          ; test for base memory 
  386.         int  12h                         ; BIOS int 12h returns memory size
  387.         push ax                          ; this is safe on an AT
  388.     mov  dx,offset newline         
  389.         call dostty
  390.     mov  dx,offset indent          
  391.         call dostty
  392.         pop  dx
  393.         call dec16out
  394.     mov  dx,offset msg41         ; kb
  395.         call dostty
  396.     mov  dx,offset msg42         ; bytes
  397.         call dostty
  398. ;
  399. ;****************************************************************************
  400. ;* Test for presence and amount of exTEnded memory (AT class machines only) *
  401. ;****************************************************************************
  402.         mov  ax,8800h
  403.         int  15h
  404.         cmp  ax,0h
  405.         je   noexten
  406.         push ax
  407.     mov  dx,offset newline         
  408.         call dostty
  409.     mov  dx,offset indent          
  410.         call dostty
  411.         pop  dx
  412.         call dec16out                    ; convert binary to decimal & display
  413.     mov  dx,offset msg41         ; kb
  414.         call dostty
  415.         jmp  extend
  416. noexten:
  417.     mov  dx,offset msg32         ; no exTEnded memory installed
  418.         call dostty
  419.     mov  dx,offset msg30
  420.         call dostty
  421.         jmp  chk_emm                     ; go see if exPAnded memory installed
  422.  
  423. extend:
  424.     mov  dx,offset msg30         ; exTEnded memory is installed
  425.         call dostty
  426.         jmp  chk_emm                     ; go see if exPAnded memory installed
  427. ;
  428. ;***********************************************************************
  429. ;* Test for machine type if not AT class.                              *
  430. ;***********************************************************************
  431. not_at:
  432.         cmp  ps2_flag,30h                ; is this a PS/2 Model 30?
  433.         je   chk_mem                     ; if yes, go right to mem chk
  434.     cmp  al,0FEh                   ; is this a PC/XT ?
  435.     jne   not_xt             ; set flag if it is, branch if not
  436.     or   byte ptr cs:config_flag,10h ; indicate PC/XT
  437.     mov  dx,offset msg21         ; 
  438.         call dostty
  439.         jmp  chk_mem
  440. not_xt:
  441.     cmp  al,0FFh                   ; is this a PC ?
  442.     jne   not_pc             ; set flag if it is, branch if not
  443.     or   byte ptr cs:config_flag,20h ; indicate PC
  444.     mov  dx,offset msg22         ; 
  445.         call dostty
  446.         jmp  chk_mem
  447. not_pc:
  448.     cmp  al,0F9h                   ; is this a PC Convertible?
  449.     jne   xt_089             ; set flag if it is, branch if not
  450.     or   byte ptr cs:config_flag,40h ; indicate PC Convertible
  451.     mov  dx,offset msg23         ; 
  452.         call dostty
  453.         jmp  chk_mem
  454.  
  455. xt_089:
  456.     cmp  al,0FBh                   ; is this a new PC/XT-089? 
  457.     jne   unk_id             ; set flag if it is, branch if not
  458.     or   byte ptr cs:config_flag,80h ; indicate PC/XT-089 
  459.     mov  dx,offset msg24         ; 
  460.         call dostty
  461.         jmp  chk_mem
  462.  
  463. unk_id:
  464.         mov  dx,offset msg4         ; don't recognize this Klone 
  465.         call dostty
  466.         mov  sav_code,al                 ; display the actual machine ID byte
  467.     mov  cx,1                     ; count of bytes to display
  468.     lea  bx,[sav_code]
  469.         call show_bytes
  470. ;
  471. ;***********************************************************************
  472. ; Test for amount of conventional memory.                              *
  473. ;***********************************************************************
  474. chk_mem:                                 ; test for main memory if not AT class 
  475.                                          ;  machine
  476.         int  12h                         ; BIOS int 12h returns memory size
  477.         push ax                          ; risky: only returns switch settings
  478.     mov  dx,offset newline         
  479.         call dostty
  480.     mov  dx,offset indent          
  481.         call dostty
  482.         pop  dx
  483.         call dec16out
  484.     mov  dx,offset msg41         ; kb
  485.         call dostty
  486.     mov  dx,offset msg42         ; bytes
  487.         call dostty
  488. ;
  489. ;***********************************************************************
  490. ;* Test for presence and amount of LIM/EMS (exPAnded) memory
  491. ;***********************************************************************
  492. ;
  493. chk_emm:
  494.         mov  ah,35h
  495.         mov  al,67h
  496.         int  21h
  497.         mov  di,0Ah
  498.         push cs
  499.         pop  ds
  500.         mov  si,offset emm_name          ; guaranteed device driver name
  501.         mov  cx,8                        ; length of file name
  502.         cld
  503.         repz cmpsb
  504.         jz   chk_ems_hardware
  505.         jmp  no_emm
  506. ;***********************************************************************
  507. ;* Find out if hardware is functional using Int 67h fcn 40h
  508. ;***********************************************************************
  509. chk_ems_hardware:
  510.         mov  ah,40h                      ;
  511.         int  67h
  512.         cmp  ah,0h                       ; zero return code means all ok
  513.         je   emm_ok
  514.         cmp  ah,80h                      ;
  515.         je   bad_drv
  516. bad_hard:
  517.     mov  dx,offset newline         ;
  518.         call dostty
  519.     mov  dx,offset indent          
  520.         call dostty
  521.     mov  dx,offset badbrd            ; bad emm hardware
  522.         call dostty
  523.         jmp  chk_bios
  524. bad_drv:
  525.     mov  dx,offset newline         
  526.         call dostty
  527.     mov  dx,offset indent          
  528.         call dostty
  529.     mov  dx,offset baddrv            ; bad emm driver image
  530.         call dostty
  531.         jmp  chk_bios
  532. ;
  533. ;***********************************************************************
  534. ;* Find out how many pages present/available using Int 67h fcn 03h
  535. ;***********************************************************************
  536. emm_ok:
  537.     mov  dx,offset newline         
  538.         call dostty
  539.     mov  dx,offset indent          
  540.         call dostty
  541.         mov  ah,42h                      ; get number of pages
  542.         int  67h
  543.         or   ah,ah
  544.         jz   no_err
  545.                                          ; put error messages here
  546.         jmp  chk_bios
  547. no_err:
  548.         mov  word ptr total_pages,dx     ; dx holds total number of 16kb pages
  549.         mov  word ptr avail_pages,bx     ; bx holds number of available pages
  550.         call dec16out                    ; display it
  551.     mov  dx,offset msg31A            ; 
  552.         call dostty
  553.     mov  dx,offset newline         
  554.         call dostty
  555.     mov  dx,offset indent          
  556.         call dostty
  557.         mov  dx,word ptr avail_pages
  558.         call dec16out                    ; display it
  559.     mov  dx,offset msg31B            ; 
  560.         call dostty
  561. ;
  562. ;***********************************************************************
  563. ;* Find out the EMS version using Int 67h fcn 07h
  564. ;***********************************************************************
  565. ;
  566.         mov  ah,46h                      ; get emm version
  567.         int  67h                         ; al = version # in BCD
  568.         mov  byte ptr emm_vers,al        ; Major revision in upper 4 bits
  569.                                          ; Minor revision in lower 4 bits
  570.     mov  dx,offset msg31C            ; 
  571.         call dostty
  572.         mov  al,byte ptr emm_vers
  573.         and  ax,00F0h                    ; isolate major ver #
  574.         mov  cl,4                        ; shift to low bits
  575.         shr  ax,cl                 
  576.         add  al,30h                      ; make it ascii
  577.         mov  dl,al                       ; set it up for stdout
  578.         call stdout                      ; display major version #
  579.         mov  dl,2Eh
  580.         call stdout                      ; display a period
  581.         mov  al,byte ptr emm_vers        ; get emm version
  582.         and  ax,000Fh                    ; isolate minor version
  583.         add  al,30h                      ; make it ascii
  584.         mov  dl,al                       ; set it up for stdout
  585.         call stdout                      ; display minor version #
  586.         jmp  chk_bios
  587.  
  588. no_emm:
  589.     mov  dx,offset msg32          ; no exPAnded memory found...
  590.         call dostty
  591.     mov  dx,offset msg31
  592.         call dostty
  593.     mov  dx,offset msg43             ; ...or the emm not installed
  594.         call dostty
  595. ;
  596. ;***********************************************************************
  597. ;* display copyright and rom release date and test for enhanced BIOS   *
  598. ;***********************************************************************
  599. chk_bios:
  600.                                          ; display copyright slug
  601.     mov  dx,offset newline         
  602.         call dostty
  603.     mov  dx,offset indent          
  604.         call dostty
  605.     mov  dx,offset copyrite         ; copyright header string
  606.         call dostty
  607.         cld
  608.         push es
  609.         push ds
  610.         push ds
  611.         pop  es                          ; destination string address in es:di
  612.         mov  ax,0F000h                   ; source string address in ds:si
  613.         mov  ds,ax                       ; ...location of IBM AT copyright
  614.         xor  ax,ax
  615.         mov  cx,10h                      ; count of words in copyright
  616.     test byte ptr cs:config_flag,10h ; is this an older PC/XT?
  617.         jz   getcopy
  618.         mov  ax,0E000h                   ; IBM XT copyright is higher up in rom
  619.         mov  cx,0Bh                      ; count of words (XT is shorter)
  620. getcopy:
  621.         mov  bx,cx                       ;
  622.         shl  bx,1                        ; multiply by 2 to get offset of 
  623.         mov  si,ax                       ; terminator character in dest string
  624.         mov  di,offset es:tbuff
  625.         rep  movsw
  626.         pop  ds
  627.         pop  es
  628.         mov  byte ptr tbuff+[bx],'$'    ; insert terminator
  629.         mov  bx, offset tbuff
  630. scan:
  631.         cmp  byte ptr[bx],'$'           ; are we done?
  632.         je   end_scan                   ; go display it
  633.         cmp  byte ptr[bx],' '           ; less than a space?
  634.         jb   hide_it                    ;
  635.         cmp  byte ptr[bx],'~'           ; greater than a tilde
  636.         jna  bump_bx                    ; if not it's printable
  637.         
  638. hide_it:
  639.         mov  byte ptr[bx],20h           ; make nonsense characters a space
  640. bump_bx:
  641.         inc  bx                         ; increment the address
  642.         jmp  scan                       ; go do it again
  643. end_scan:
  644.         mov  dx,offset tbuff            ; 
  645.         call dostty
  646.         push es
  647.         push ds
  648.         push ds
  649.         pop  es                          ; destination string address in es:di
  650.     mov  dx,offset newline         
  651.         call dostty
  652.     mov  dx,offset indent          
  653.         call dostty
  654.     mov  dx,offset biosdate         ; date header
  655.         call dostty
  656.         mov  ax,0F000h                   ; source string address in ds:si
  657.         mov  ds,ax
  658.         mov  ax,0FFF5h                    ;offset of rom release date
  659.         mov  si,ax
  660.         mov  di,offset es:tbuff
  661.         mov  cx,04h                      ; count of words
  662.         rep  movsw
  663.         pop  ds
  664.         pop  es
  665.         mov  byte ptr tbuff[08h],'$'     ; insert string terminator
  666.         mov  dx,offset tbuff             
  667.         call dostty
  668.                                          ; check for enhanced bios
  669.         mov  ah,2                        ; get shift status (old function)
  670.         int  16h                         ;  
  671.         mov  bl,al                       ; Save shift status
  672.         not  al                          ; change al (invert all bits)
  673.         mov  ah,12h                      ; new BIOS extended shift status
  674.         int  16h                         ; 
  675.         cmp  al,bl                       ; is result the same from both calls?
  676.         jne  next1                       ; if not, this is not enhanced BIOS
  677.         or   byte ptr cs:config_flag,02h ; indicate enhanced BIOS present
  678.     mov  ax,40h                 ; seg address of BIOS data area
  679.     mov  es,ax                       ; establish addressibility
  680.     mov  al,byte ptr es:[96h]     ; offset of BIOS @KB_FLAG_3 byte
  681.     test al,10h                   ; is enhanced keyboard attached?
  682.     jz   next1               ; set flag if it is, branch if not
  683.         or   byte ptr cs:config_flag,04h ; indicate enhanced keyboard attached
  684.         test byte ptr cs:config_flag,06h ; could be new XTs with enhanced BIOS 
  685.     jz   next1                       ; branch if not
  686.     add  get_key,10h                 ; if new bios...
  687.     add  avail_c,10h                 ; ...and new keyboard...
  688.     add  get_sts,10h                 ; ...add 10h to get extended functions
  689.  
  690. next1:
  691.         test byte ptr cs:config_flag,02h ; is enhanced BIOS present?
  692.     jz   old_bios             ; branch if not
  693.     mov  dx,offset msg2
  694.         call dostty
  695.         jmp  new_bios
  696. old_bios:
  697.     mov  dx,offset msg5
  698.         call dostty
  699. new_bios:
  700.         test byte ptr cs:config_flag,04h ; is enhanced keyboard present?
  701.     jz   not_enhanced            ; branch if not
  702.     mov  dx,offset msg3         ; 
  703.         call dostty
  704.         mov  scan_code,86h               ; ascii code for F12
  705.     jmp  scan_rom
  706. not_enhanced:
  707.     mov  dx,offset msg6
  708.         call dostty
  709.  
  710. ;***********************************************************************
  711. ;* Scan ROM for BIOS IDs...
  712. ;***********************************************************************
  713. scan_rom:
  714.         mov  dx,0C000h                   ; start point for rom signature scan
  715.         mov  di,word ptr rom_sig         ; rom signature is 55 AA hex
  716. scan_loop:
  717.         mov  es,dx 
  718.         xor  bx,bx                       ; offset zero
  719.         mov  ax,es:[bx]                  ; 
  720.         cmp  ax,di                       ; equal to 55 AA ?
  721.         jnz  next_blk                    ; if no, go increment block address
  722.         mov  ax,es                       ; get segment address for display
  723.         push dx
  724.     mov  dx,offset newline         
  725.         call dostty
  726.     mov  dx,offset indent          
  727.         call dostty
  728.     mov  dx,offset romid             ; ROM detected message
  729.         call dostty
  730.         call disp_hex
  731.         mov  al,'h'
  732.         call stdout
  733.         mov  rom_flag,0h                 ; indicate an adapter ROM was found
  734.         pop  dx
  735. next_blk:
  736.         add  dx,80h                      ; point to next 2k address
  737. chk_addr:
  738.         cmp  dx,0F600h                   ; end of addresses where ROMs can be?
  739.         jl   scan_loop                   ; search for more if not
  740. no_roms:
  741.         cmp  rom_flag,0h                 ; was an adapter ROM found?
  742.         je   end_rom                     ; yes? bypass message
  743.     mov  dx,offset newline         
  744.         call dostty
  745.     mov  dx,offset indent          
  746.         call dostty
  747.     mov  dx,offset noroms            ; no ROMs detected
  748.         call dostty
  749. end_rom:
  750. ;
  751. ;***********************************************************************
  752. ;* Check active display and adapter
  753. ;***********************************************************************
  754. ;
  755. chkdisp:                                 ; check for presence of an EGA first
  756.         mov  bx, 0FF10h                  ; see if EGA responds
  757.         mov  ah, 12h
  758.         int  10h
  759.         test bh, 0FEh                    ; bl has mem size
  760.         jnz  notega                      ; cl has switch settings
  761.         jmp  IsEga
  762.  
  763. notega:                                  ; see if MDA or CGA or HGC    
  764.     mov  ax,40h                 ; seg address of BIOS data area
  765.     mov  es,ax                       ; establish addressibility
  766.     mov  al,byte ptr es:[10h]     ; offset of video status byte
  767.     and  al,00110000b                ; isolate bits 4 & 5
  768.     cmp  al,30h                      ; is it monochrome card?
  769.     je   is_mono                     ; assume color if not mono
  770.     mov  dx,offset msg19A         ; CGA is active adapter
  771.         call dostty
  772.         jmp     chk_ndp
  773.  
  774. is_mono:
  775.     mov  dx,offset msg20         ; MDA is active adapter
  776.         call dostty
  777.         jmp     chk_ndp
  778. IsEga:
  779.         call ega_copy                    ; bl and cl get clobbered
  780.     mov  al,byte ptr es:[87h]     ; offset of EGA BIOS data byte INFO
  781.     shl  al,1
  782.     shl  al,1
  783.     shl  al,1
  784.     shl  al,1
  785.     test al,0h                   ; look for EGA with color
  786.     jnz  nocolor             ; if not, see if mono attached
  787.     mov  dx,offset msg9         ; EGA is active adapter
  788.         call dostty
  789.     mov  al,byte ptr es:[88h]     ; offset of EGA BIOS data byte INFO_3
  790.     shl  al,1
  791.     shl  al,1
  792.     shl  al,1
  793.     shl  al,1
  794.     test al,09h                   ; EGA with ECD in hi res mode
  795.     jnz  nothires             ; set flag if it is, branch if not
  796.     mov  dx,offset msg18         ; 
  797.         call dostty
  798.         jmp  chkmem
  799. nothires:    
  800.     test al,01h                   ; EGA with ECD, EGA in CGA mode
  801.     jnz  noecd             ; set flag if it is, branch if not
  802.     mov  dx,offset msg18A        ; ECD is in CGD emulation mode
  803.         call dostty
  804.         jmp  chkmem
  805. noecd:
  806.     test al,0Eh                   ; EGA with Normal Color Display
  807.     jnz  nocolor             ; set flag if it is, branch if not
  808.     mov  dx,offset msg19         ; 
  809.         call dostty
  810.         jmp  chkmem
  811.  
  812. nocolor:
  813.     test al,0Dh                   ; look for EGA with monochrome display
  814.     jnz  mono2             ; set flag if it is, branch if not
  815.     mov  dx,offset msg20         ; 
  816.         call dostty
  817.         jmp  chkmem
  818. mono2:
  819.     test al,05h                   ; look for EGA with monochrome display
  820.     jnz  badswitch             ; set flag if it is, branch if not
  821.     mov  dx,offset msg20         ; 
  822.         call dostty
  823.         jmp  chkmem
  824. badswitch:                               ; switches must be set incorrectly
  825.     mov  dx,offset msg25         ; 
  826.         call dostty
  827.  
  828. ;
  829. ;***********************************************************************
  830. ;* Test for amount of graphics memory on EGA
  831. ;***********************************************************************
  832. ;
  833. chkmem:
  834.         mov  ax,40h
  835.         mov  es,ax
  836.     mov  al,byte ptr es:[87h]     ; offset of EGA BIOS data byte INFO
  837.     and  al,60h                      ; get rid of unwanted bits
  838.     cmp  al,60h                      ; is 256kb onboard?
  839.     jne  not256                      ; no - check for 192kb
  840.     mov  dx,offset msg17         ; 
  841.         call dostty
  842.         jmp  chk_ndp
  843.  
  844. not256:
  845.     cmp  al,40h                      ; is 192kb onboard? (is IBM EGA)
  846.     jne  not192                      ; no - check for 128kb
  847.     mov  dx,offset msg16         ; 
  848.         call dostty
  849.         jmp  chk_ndp
  850.  
  851. not192:
  852.     cmp  al,20h                      ; is 128kb onboard? (is IBM EGA)
  853.     jne  not128                      ; no - check for 64kb
  854.     mov  dx,offset msg15         ; 
  855.         call dostty
  856.         jmp  chk_ndp
  857.  
  858. not128:                                  ; *must* be 64kb memory (is IBM EGA)
  859.     mov  dx,offset msg14         ; 
  860.         call dostty
  861.         jmp  chk_ndp
  862.  
  863. ;
  864. ;***********************************************************************
  865. ;* Test for presence of 80x87.                                         * 
  866. ;***********************************************************************
  867. ;
  868. chk_ndp:
  869.     fninit                  ; finit - see if 8087 installed
  870.     sub  ax,ax              ; fn means no wait in case no ndp
  871.     mov  word ptr control,ax    ; move two zeros to cntrl reg save area
  872.     fnstcw control                 ; get 8087 control word - no wait
  873.     mov  ax,word ptr control    ; put control word in ax
  874.     and  ax,037Fh                ; default initialization state
  875.     cmp  ax,037Fh                ; equal to 8087 here?
  876.     jne  no_ndp            ; no - go around
  877.     cmp  ps2_flag,30h               ; is it a PS/2 model 50 or above?
  878.         ja   is_80287                   ; if so it's an 80287
  879.     test byte ptr config_flag,01h   ; is this an 80286 class machine ?
  880.         jz   is_8087                    ; if not, NDP is 8087
  881. is_80287:
  882.     mov  dx,offset msg28            ; else it's an 80287
  883.     call dostty
  884.         jmp  getvers
  885. is_8087:
  886.     mov  dx,offset msg27
  887.     call dostty
  888.         jmp  getvers
  889. no_ndp:    
  890.     mov  dx,offset msg29
  891.     call dostty
  892. ;
  893. ;***********************************************************************
  894. ;* Display DOS Version
  895. ;***********************************************************************
  896. ;
  897. getvers:
  898.     mov  dx,offset msg33
  899.     call dostty
  900.         mov  ax,dos_vers
  901.     cmp  ax,0200h                 ; 2.00 or greater?
  902.     ja   isver3
  903.     mov  dx,offset msg38             ; it's 2.00
  904.     call dostty
  905.     jmp  endvers
  906.  
  907. isver3:
  908.     cmp  ax,0300h                 ; 3.00 or greater?
  909.         jae  which3
  910.     mov  dx,offset msg39             ; no, must be 2.10
  911.     call dostty
  912.     jmp  endvers
  913.  
  914. which3:
  915.     cmp  al,0Ah                 ; 3.10 ?
  916.     jne  mustbe32
  917.     mov  dx,offset msg36
  918.     call dostty
  919.     jmp  endvers
  920. mustbe32:
  921.     cmp  al,14h                 ; 3.20 ?
  922.     jne  mustbe33
  923.     mov  dx,offset msg37             ; 3.20
  924.     call dostty
  925.     jmp  endvers
  926. mustbe33:
  927.     cmp  al,1Eh                 ; 3.30 ?
  928.     jne  unk_dos
  929.     mov  dx,offset msg37A            ; 3.30
  930.     call dostty
  931.     jmp  endvers
  932. unk_dos:
  933.     mov  dx,offset msg40             ; unknown version number
  934.     call dostty
  935.     jmp  quit
  936. endvers:
  937. ;
  938. ;***********************************************************************
  939. ;* Display the active switch character
  940. ;***********************************************************************
  941.         cmp  switch_err,0h               ; was there a switchar error?
  942.         je   fcn_37_ok
  943.     mov  dx,offset msg33B
  944.     call dostty
  945. fcn_37_ok:
  946.     mov  dx,offset msg33A
  947.     call dostty
  948.         mov  al,switchar                 ; display the *current* switchar
  949.         call stdout
  950. ;
  951. ;***********************************************************************
  952. ;* Display the active Lpt: ports
  953. ;***********************************************************************
  954. ;
  955. chklpt:
  956.         mov  ax,40h                      ; ROM BIOS data area segment address
  957.         mov  es,ax
  958.         mov  ax,word ptr es:[8h]         ; offset of lpt I/O addresses
  959.         cmp  ax,0h
  960.         je   no_lpt1
  961.         inc  portcnt
  962.     mov  dx,offset newline         
  963.         call dostty
  964.     mov  dx,offset indent          
  965.         call dostty
  966.     mov  dx,offset msg44             ; lpt1:
  967.     call dostty
  968.         call disp_hex
  969.         mov  al,'h'
  970.         call stdout
  971. no_lpt1:
  972.         mov  ax,word ptr es:[0Ah]
  973.         cmp  ax,0h
  974.         je   no_lpt2
  975.         inc  portcnt
  976.     mov  dx,offset newline         
  977.         call dostty
  978.     mov  dx,offset indent          
  979.         call dostty
  980.     mov  dx,offset msg45             ; lpt2:
  981.     call dostty
  982.         call disp_hex
  983.         mov  al,'h'
  984.         call stdout
  985. no_lpt2:
  986.         mov  ax,word ptr es:[0Ch]
  987.         cmp  ax,0h
  988.         je   no_lpt3
  989.         inc  portcnt
  990.     mov  dx,offset newline         
  991.         call dostty
  992.     mov  dx,offset indent          
  993.         call dostty
  994.     mov  dx,offset msg46             ; lpt3:
  995.     call dostty
  996.         call disp_hex
  997.         mov  al,'h'
  998.         call stdout
  999. no_lpt3:
  1000.         cmp  portcnt,0h
  1001.         je   no_prns
  1002.         jmp  chkcom
  1003. no_prns:
  1004.     mov  dx,offset newline         
  1005.         call dostty
  1006.     mov  dx,offset indent          
  1007.         call dostty
  1008.     mov  dx,offset msg49             ; no lpt ports found
  1009.     call dostty
  1010. ;
  1011. ;***********************************************************************
  1012. ;* Display the active Com: ports
  1013. ;***********************************************************************
  1014. ;
  1015.  
  1016. chkcom:
  1017.         and  portcnt,0h
  1018.         mov  ax,word ptr es:[0h]         ; offset of com I/O addresses
  1019.         cmp  ax,0h
  1020.         je   no_com1
  1021.         inc  portcnt
  1022.     mov  dx,offset newline         
  1023.         call dostty
  1024.     mov  dx,offset indent          
  1025.         call dostty
  1026.     mov  dx,offset msg47             ; com1:
  1027.     call dostty
  1028.         call disp_hex
  1029.         mov  al,'h'
  1030.         call stdout
  1031. no_com1:
  1032.         mov  ax,word ptr es:[02h]
  1033.         cmp  ax,0h
  1034.         je   no_com2
  1035.         inc  portcnt
  1036.     mov  dx,offset newline         
  1037.         call dostty
  1038.     mov  dx,offset indent          
  1039.         call dostty
  1040.     mov  dx,offset msg48             ; com2:
  1041.     call dostty
  1042.         call disp_hex
  1043.         mov  al,'h'
  1044.         call stdout
  1045. no_com2:
  1046.         mov  ax,word ptr es:[04h]
  1047.         cmp  ax,0h
  1048.         je   no_com3
  1049.         inc  portcnt
  1050.     mov  dx,offset newline         
  1051.         call dostty
  1052.     mov  dx,offset indent          
  1053.         call dostty
  1054.     mov  dx,offset msg48A            ; com3: 
  1055.     call dostty
  1056.         call disp_hex
  1057.         mov  al,'h'
  1058.         call stdout
  1059. no_com3:
  1060.         mov  ax,word ptr es:[06h]
  1061.         cmp  ax,0h
  1062.         je   no_com4
  1063.         inc  portcnt
  1064.     mov  dx,offset newline         
  1065.         call dostty
  1066.     mov  dx,offset indent          
  1067.         call dostty
  1068.     mov  dx,offset msg48B            ; com4: 
  1069.     call dostty
  1070.         call disp_hex
  1071.         mov  al,'h'
  1072.         call stdout
  1073. no_com4:
  1074.         cmp  portcnt,0h
  1075.         je   no_coms
  1076.         jmp  next_chk
  1077. no_coms:
  1078.     mov  dx,offset newline         
  1079.         call dostty
  1080.     mov  dx,offset indent          
  1081.         call dostty
  1082.     mov  dx,offset msg50             ; no com ports found
  1083.     call dostty
  1084. next_chk:
  1085.         dec  optcnt
  1086.     call pause
  1087.  
  1088. ;***********************************************************************
  1089. ;* Display DOS Invar Table Contents.                                   *
  1090. ;***********************************************************************
  1091. invar_chk:
  1092.         cmp  inv_flag,0FFh               ; switch set for invar list?
  1093.         je   disp_invar                  ; yes
  1094.         jmp  chk_dev_drv                 ; no - bypass it.
  1095. disp_invar:                              ; list "Invars" table contents
  1096.     mov  dx,offset newline         
  1097.         call dostty
  1098.     mov  dx,offset scr1
  1099.     call dostty
  1100.     mov  dx,offset newline         
  1101.         call dostty
  1102.     mov  dx,offset space1
  1103.         call dostty
  1104.         mov  ah,52h                      ; undocumented function DOS 2.x or...
  1105.         int  21h                         ; ...greater. Returns pointer to a...
  1106.         push es                          ; ... DOS internal structure in es:bx
  1107.         push bx                          ; save for later
  1108.         push bx                          ;
  1109.         pop  sav_off                     ;
  1110.         mov  ax,es                       ; get Invars seg address for display
  1111.         call disp_hex                    ; display it.
  1112.         call split                       ; print the colon.
  1113.         mov  bx,sav_off                  ; restore offset
  1114.         mov  ax,bx                       ; get Invars off address for display
  1115.         call disp_hex
  1116.     mov  dx,offset space4
  1117.         call dostty
  1118.         mov  bx,sav_off                  ; restore offset
  1119.         mov  ax,es:[bx+2]                ; get DPB segment address for display
  1120.         mov  dpb_seg,ax
  1121.         call disp_hex
  1122.         call split
  1123.         mov  bx,sav_off                  ; restore offset
  1124.         mov  ax,es:[bx]                  ; get DPB offset address for display
  1125.         mov  dpb_off,ax
  1126.         call disp_hex
  1127.     mov  dx,offset space4
  1128.         call dostty
  1129.         mov  bx,sav_off                  ; restore offset
  1130.         mov  ax,es:[bx+6]                ; get cache buffer seg addr 
  1131.         call disp_hex
  1132.         call split
  1133.         mov  bx,sav_off                  ; restore offset
  1134.         mov  ax,es:[bx+4]                ; get cache buffer offset addr 
  1135.         call disp_hex
  1136.     mov  dx,offset space6
  1137.         call dostty
  1138.         mov  bx,sav_off                  ; restore offset
  1139.         mov  ax,es:[bx+10h]              ; get cache buffer size for display
  1140.         add  ax,10h                      ; add in size of overhead bytes (16)
  1141.         call disp_hex
  1142.     mov  dx,offset space8
  1143.         call dostty
  1144.         mov  bx,sav_off                  ; restore offset
  1145.         mov  ax,es:[bx+18h]              ; get drive/directory table seg addr 
  1146.         call disp_hex
  1147.         call split
  1148.         mov  bx,sav_off                  ; restore offset
  1149.         mov  ax,es:[bx+16h]              ; get drive/directory table off addr 
  1150.         call disp_hex
  1151.     mov  dx,offset space5
  1152.         call dostty
  1153.         mov  ah,34h                      ; svc 34h = get DOS "Busy" flag addr
  1154.         int  21h
  1155.         push bx
  1156.         pop  sav_off
  1157.         mov  ax,es                       ; get DOS busy seg address for display
  1158.         call disp_hex
  1159.         call split
  1160.         mov  bx,sav_off                  ; restore offset
  1161.         mov  ax,bx                       ; get DOS busy off address for display
  1162.         call disp_hex
  1163. ;
  1164. ;***********************************************************************
  1165. ;* Display Disk Paramter Blocks.
  1166. ;***********************************************************************
  1167. dpb:
  1168.     mov  dx,offset newline         
  1169.         call dostty
  1170.     mov  dx,offset scr1A
  1171.     call dostty
  1172.     mov  ax,dpb_seg
  1173.     mov  es,ax
  1174.     mov  bx,dpb_off
  1175. dpb_loop:
  1176.     mov  dx,offset newline         
  1177.         call dostty
  1178.         mov  al,byte ptr es:[bx]         ; get drive id
  1179.         add  al,41h                      ; convert to ascii letter
  1180.         call stdout
  1181.         call split
  1182.     mov  dx,offset space2
  1183.         call dostty
  1184.         mov  al,byte ptr es:[bx+01h]     ; get unit number (watch VDISKs)
  1185.                                          ; media descriptor FEh indicates vdisk?
  1186.         add  al,31h                      ; convert to ascii numeral
  1187.         call stdout
  1188.     mov  dx,offset space2
  1189.         call dostty
  1190.         mov  ax,word ptr es:[bx+02h]     ; bytes per sector
  1191.         mov  cx,word ptr es:[bx+05h]     ; num of bits to shift BPS to get BPC
  1192.         shl  ax,cl                       ; multiply it
  1193.         call disp_hex
  1194.     mov  dx,offset space2         ; 
  1195.         call dostty
  1196.         mov  al,byte ptr es:[bx+04h]     ; get Sectors Per Cluster minus 1
  1197.         cmp  al,0FEh                     ; this value indicates that ...
  1198.         je   not_read                    ; ... the drive was never accessed
  1199.         jmp  was_read
  1200. not_read:
  1201.     mov  dx,offset notread
  1202.         call dostty
  1203.     mov  dx,offset space2
  1204.         call dostty
  1205.         jmp  res_sect
  1206. was_read:
  1207.         inc  al                          ; make SPC-1 SPC
  1208.         add  al,30h                      ; make ascii char
  1209.         call stdout
  1210.     mov  dx,offset space3
  1211.         call dostty
  1212. res_sect:
  1213.         mov  ax,word ptr es:[bx+06h]     ; Reserved Sectors
  1214.         call disp_hex
  1215.     mov  dx,offset space2
  1216.         call dostty
  1217.         mov  al,byte ptr es:[bx+08h]     ; get Copies of FAT
  1218.         add  al,30h                      ; make ascii char
  1219.         call stdout
  1220.     mov  dx,offset space2
  1221.         call dostty
  1222.         mov  ax,word ptr es:[bx+09h]     ; Maximum Directory Entries
  1223.         call disp_hex
  1224.     mov  dx,offset space2
  1225.         call dostty
  1226.         mov  ax,word ptr es:[bx+0Bh]     ; First Usable Sector
  1227.         call disp_hex
  1228.     mov  dx,offset space2
  1229.         call dostty
  1230.         mov  ax,word ptr es:[bx+0Dh]     ; Total Cluster Count plus 1
  1231.         dec  ax                          ; make it TCC
  1232.         call disp_hex
  1233.     mov  dx,offset space3
  1234.         call dostty
  1235.         mov  al,byte ptr es:[bx+0Fh]     ; get Sectors in FAT
  1236.         mov  sav_code,al                 ; display low order byte
  1237.     mov  cx,1                     ; count of bytes to display
  1238.         push bx
  1239.     lea  bx,[sav_code]
  1240.         call show_bytes
  1241.         pop  bx
  1242.     mov  dx,offset space2
  1243.         call dostty
  1244.         mov  ax,word ptr es:[bx+10h]     ; get First Directory Sector
  1245.         call disp_hex
  1246.     mov  dx,offset space2
  1247.         call dostty
  1248.         mov  ax,word ptr es:[bx+14h]     ; get dev drv seg addr 
  1249.         call disp_hex
  1250.         call split
  1251.         mov  ax,word ptr es:[bx+12h]     ; get dev drv off addr 
  1252.         call disp_hex
  1253.     mov  dx,offset space2
  1254.         call dostty
  1255.         mov  ax,word ptr es:[bx+16h]     ; get Media Descriptor
  1256.         cmp  al,00h                      ; if zero, drive was never accessed
  1257.         jne  good_md
  1258.     mov  dx,offset notread
  1259.         call dostty
  1260.     mov  dx,offset space2
  1261.         call dostty
  1262.         jmp  next_link
  1263. good_md:
  1264.         mov  sav_code,al                 ; display low order byte
  1265.     mov  cx,1                     ; count of bytes to display
  1266.         push bx
  1267.     lea  bx,[sav_code]
  1268.         call show_bytes
  1269.         pop  bx
  1270.     mov  dx,offset space2
  1271.         call dostty
  1272. next_link:
  1273.         mov  dx,word ptr es:[bx+18h]     ; get off of next dpb
  1274.         cmp  dx,0FFFFh                   ; last dpb in chain?
  1275.         jne  next_dpb
  1276.         jmp  end_dpb
  1277. next_dpb:
  1278.         mov  ax,word ptr es:[bx+1Ah]     ; get next DPB seg addr 
  1279.         call disp_hex
  1280.         call split
  1281.         mov  ax,word ptr es:[bx+18h]     ; get next DPB off addr 
  1282.         call disp_hex
  1283.         mov  ax,word ptr es:[bx+1Ah]     ; get seg of next dpb
  1284.         mov  dx,word ptr es:[bx+18h]     ; get off of next dpb
  1285.         mov  es,ax                       ; establish addressibility
  1286.         mov  bx,dx
  1287.         jmp  dpb_loop
  1288. end_dpb:
  1289.     mov  dx,offset lastdpb
  1290.         call dostty
  1291.     mov  dx,offset newline
  1292.         call dostty
  1293.         dec  optcnt
  1294.         call pause
  1295.         pop  bx
  1296.         pop  es
  1297. ;
  1298. ;***********************************************************************
  1299. ;* Display Device Driver Info.
  1300. ;***********************************************************************
  1301. chk_dev_drv:
  1302.         cmp  drv_flag,0FFh               ; switch set for device driver list?
  1303.         je   nul_dev                     ; yes
  1304.         jmp  chk_tsr                     ; no - bypass driver list
  1305.  
  1306. nul_dev:                                 ; list device driver section
  1307.         mov  ah,52h                      ; undocumented function DOS 2.x or...
  1308.         int  21h                         ; ...greater. Returns pointer to a...
  1309.         push es                          ; ... DOS internal structure in es:bx
  1310.         push bx                          ; save for later
  1311.     mov  dx,offset newline         
  1312.         call dostty
  1313.     mov  dx,offset scr2              
  1314.     call dostty
  1315.     pop  bx
  1316.     pop  es
  1317.         cmp  dos_vers+1,03h              ; Version dependent...
  1318.         je   add_34                      ;
  1319.         add  bx,17h                      ; add 23 byte offset if DOS 2.x
  1320.         jmp  is_two
  1321. add_34:
  1322.         add  bx,22h                      ; add 34 byte offset if DOS 3.x
  1323. is_two:
  1324.         mov  devh_seg,es                 ; segment of device header chain in es
  1325.         mov  devh_off,bx                 ; offset of NUL device now in bx
  1326.         mov  ax,es:[bx+2]                ; get seg of next driver in chain
  1327.         mov  next_seg,ax                 ; save it
  1328.         mov  ax,es:[bx]                  ; get offset of next driver in chain       
  1329.         mov  next_off,ax                 ; save it
  1330.  
  1331. drv_loop:
  1332.         cmp  ax,0FFFFh                   ; end of chain?
  1333.         jne  more_drv
  1334.         jmp  end_drv
  1335. more_drv:
  1336.         mov  ax,es:[bx+2]                ; get seg of next driver in chain
  1337.         mov  next_seg,ax                 ; save it
  1338.         mov  ax,es:[bx]                  ; get off of next driver in chain       
  1339.         mov  next_off,ax                 ; save it
  1340.     mov  dx,offset newline         
  1341.         call dostty
  1342.         mov  sav_off,bx                  ; save offset
  1343.         mov  ax,es:[bx+04h]              ; attribute word
  1344.         mov  type_drv,ax                 ; put it where I can get it
  1345.         test ax,8000h                    ; what kind of device: blk or char?
  1346.         jz   is_block
  1347.         mov  dx,offset char_dev          ; is character device
  1348.         call dostty                      ; display the word "Char"
  1349.         jmp  is_char
  1350. is_block:
  1351.         mov  dx,offset blk_dev           ; is block device
  1352.         call dostty                      ; display the word "Block"
  1353.         call blk_name                    ; format the block device name
  1354.         jmp  clean_up_name
  1355. is_char:
  1356.         mov  ax,word ptr es:[bx+0Ah]     ; move name to my buffer
  1357.         mov  word ptr sav_name+0,ax
  1358.         mov  ax,word ptr es:[bx+0Ch]
  1359.         mov  word ptr sav_name+2,ax
  1360.         mov  ax,word ptr es:[bx+0Eh]
  1361.         mov  word ptr sav_name+4,ax
  1362.         mov  ax,word ptr es:[bx+10h]
  1363.         mov  word ptr sav_name+6,ax
  1364.         mov  ax,2020h                    ; pad name to 12 chars
  1365.         mov  word ptr sav_name+8,ax
  1366.         mov  word ptr sav_name+10,ax
  1367.         mov  word ptr sav_name+12,ax
  1368.         mov  byte ptr sav_name+13,0FFh   ; the field termination character
  1369. clean_up_name:
  1370.         push bx
  1371.         mov  bx, offset sav_name
  1372. scan2:
  1373.         cmp  byte ptr[bx],0FFh           ; are we done? 
  1374.         je   end_scan2                   ; go display it
  1375.         cmp  byte ptr[bx],20h            ; less than a space?
  1376.         jb   hide_it2
  1377.         cmp  byte ptr[bx],'z'            ; greater than lower case z?
  1378.         jna  bump_bx2                    ; if not it's printable
  1379.         
  1380. hide_it2:
  1381.         mov  byte ptr[bx],20h            ; make nonsense characters a space
  1382. bump_bx2:
  1383.         inc  bx                          ; increment the address
  1384.         jmp  scan2                       ; go do it again
  1385. end_scan2:
  1386.         pop  bx
  1387.         mov  dx,offset sav_name          ; print dev name even if block dev
  1388.         call disp_dev_drv
  1389.         mov  dx,offset space2
  1390.         call dostty
  1391.         mov  ax,es                       ; get this driver's seg addr
  1392.         call disp_hex
  1393.         call split
  1394.  
  1395.         mov  bx,sav_off                  ; restore offset
  1396.         mov  ax,bx                       ; get this driver's off addr
  1397.         call disp_hex
  1398.     mov  dx,offset space7         ; 
  1399.         call dostty
  1400.  
  1401.                                          ; strategy offset
  1402.         mov  bx,sav_off                  ; restore offset
  1403.         mov  ax,es:[bx+06h]              ; get strategy offset
  1404.         call disp_hex
  1405.     mov  dx,offset space3         ; 
  1406.         call dostty
  1407.  
  1408.                                          ; interrupt offset
  1409.         mov  bx,sav_off                  ; restore offset
  1410.         mov  ax,word ptr es:[bx+08h]     ; get interrupt offset
  1411.         call disp_hex
  1412.     mov  dx,offset space6         ; 
  1413.         call dostty
  1414.  
  1415.         mov  bx,sav_off                  ; restore offset
  1416.         mov  ax,word ptr es:[bx+04h]     ; get device attribute word
  1417.         call disp_hex
  1418.  
  1419.     mov  dx,offset space5         ; 
  1420.         call dostty
  1421.         mov  ax,type_drv                 ; check DOS version this driver
  1422.         and  ah,08h                      ; ...requires
  1423.         cmp  ah,08h                      ;
  1424.         jne  not_rm                      ; OCREM not supported - a 2.x driver
  1425.         mov  dx,offset msg99             ; OCREM is  supported - a 3.x driver
  1426.         jmp  is_rm
  1427. not_rm:
  1428.         mov  dx,offset msg98
  1429. is_rm:
  1430.         call dostty
  1431.         mov  bx,sav_off                  ; restore offset
  1432.         mov  es,next_seg                 ; get seg of next driver in chain
  1433.         mov  bx,next_off                 ; get off of next driver in chain       
  1434.         mov  ax,bx                       ; set up check for end of chain
  1435.         jmp  drv_loop
  1436. end_drv:
  1437.         dec  optcnt
  1438.     call pause
  1439.  
  1440. ;***********************************************************************
  1441. ;* Display Memory Control Blocks
  1442. ;***********************************************************************
  1443. chk_tsr:                                 ; list MCBs
  1444.         cmp  mem_flag,0FFh               ; switch set for MCB list?
  1445.         je   mem_alloc                   ; yes - go do it
  1446.         jmp  quit                        ; no - quit
  1447.  
  1448. mem_alloc:
  1449.     mov  dx,offset newline         
  1450.         call dostty
  1451.     mov  dx,offset scr3              ; Memory Allocation Screen
  1452.     call dostty
  1453.         mov  ah,52h
  1454.         int  21h
  1455.     mov  ax,es:[bx-2]                ; contains seg address of 1st MCB
  1456.     mov  es,ax                       ; establish addressibility
  1457.     xor  bx,bx                       ; offset will always be zero
  1458.  
  1459. mcb_loop:
  1460.         and  env_flag,0h                 ; set environment found flag "off"
  1461.         and  psp_flag,0h                 ; set PSP found flag "off"
  1462.         and  sys_flag,0h                 ; set system block found flag "off"
  1463.         and  tsr_flag,0h                 ; set TSR flag "off"
  1464.         and  mt_flag,0h                  ; set empty block found flag "off"
  1465.  
  1466.         cmp  byte ptr es:[bx],5Ah        ; hex 5A is last MCB
  1467.         jne  mcb_2
  1468.         jmp  last_mcb                    ; process last one differently
  1469. mcb_2:
  1470.         mov  mcbseg,ax                   ; save for later
  1471.     mov  dx,offset newline         
  1472.         call dostty
  1473.     xor  bx,bx                       ; offset will always be zero
  1474.         call disp_hex
  1475.         mov  dx, offset space2           ; will change as logic is inserted
  1476.         call dostty
  1477.     xor  bx,bx                       
  1478. chk_sys:
  1479.         mov  ax,word ptr es:[bx+1]       ; get seg addr this MCB allocates for
  1480.         cmp  ax,0008h                    ; DOS block always has 0008h here
  1481.         jne  chk_dealloc
  1482.         or   sys_flag,0FFh
  1483.         and  firstsys,0h
  1484. chk_dealloc:                             ; was this block deallocated?
  1485.         push ax
  1486.         mov  ax,word ptr es:[bx+1]       ; get seg addr this MCB allocates for
  1487.         call disp_hex
  1488.         mov  dx, offset space3
  1489.         call dostty
  1490.     xor  bx,bx                       ; offset will always be zero
  1491.         pop  ax
  1492.         cmp  ax,0000h                    ; is block begin zero?
  1493.         jne  paras                       ; if yes, this is empty block
  1494.         or   mt_flag,0FFh                ; set flag (block was deallocated)
  1495. paras:
  1496.         mov  ax,word ptr es:[bx+3]       ; get number of paragraphs allocated
  1497.         call disp_hex
  1498.         mov  dx, offset space2
  1499.         call dostty
  1500.     xor  bx,bx                       ; 
  1501. search_for_env:                          ; does this MCB allocate for an Env?
  1502.         and  env_flag,0h                 ; clear flag
  1503.         cmp  byte ptr es:[bx+10h],43h    ; looking for "C" in "COMSPEC="
  1504.         jne  no_autoexec              ; yes = last MCB controls environment
  1505.         cmp  byte ptr es:[bx+11h],4Fh    ; looking for "O" in "COMSPEC="
  1506.         jne  no_autoexec                 ; if not, maybe no autoexec.bat
  1507.         jmp  env_found
  1508. no_autoexec:                             ; if no autoexec, 1st string is PATH=
  1509.         cmp  byte ptr es:[bx+10h],50h    ; looking for "P" in "PATH="
  1510.         jne  search_for_psp              ; yes = last MCB controls environment
  1511.         cmp  byte ptr es:[bx+11h],41h    ; looking for "A" in "PATH="
  1512.         jne  search_for_psp              ; if not, no environment
  1513. env_found:
  1514.         cmp  firstenv,01h                ; first environment? 
  1515.         je   first_env
  1516.         call get_name                    ; get the name of the process
  1517.         or   tsr_flag,0FFh
  1518. first_env:
  1519.         and  psp_flag,0h                 ; can't be both
  1520.         or   env_flag,0FFh               ; set flag
  1521.         jmp  type_blk
  1522.  
  1523. search_for_psp:                          ; does this MCB allocate for a PSP?
  1524.         and  psp_flag,0h                 ; clear flag
  1525.         cmp  byte ptr es:[bx+10h],0CDh   ; looking for an Int 20h in PSP
  1526.         jne  type_blk
  1527.         cmp  byte ptr es:[bx+11h],20h    ; 
  1528.         jne  type_blk
  1529.         and  env_flag,0h                 ; can't be both
  1530.         or   psp_flag,0FFh               ; set flag for others
  1531.         xor  bx,bx
  1532.         cmp  firstpsp,01h
  1533.         je   type_blk
  1534.         or   tsr_flag,0FFh
  1535. type_blk:
  1536.         cmp  psp_flag,0FFh               ; PSP?
  1537.         jne  type2 
  1538.         mov  dx,offset psptype
  1539.         jmp  end_type
  1540. type2:
  1541.         cmp  env_flag,0FFh               ; environment? 
  1542.         jne  type3 
  1543.         mov  dx,offset envtype
  1544.         jmp  end_type
  1545.  
  1546. type3:
  1547.         cmp  mt_flag,0FFh                ; empty block?
  1548.         jne  type4 
  1549.         mov  dx,offset mttype
  1550.         jmp  end_type
  1551. type4:
  1552.         cmp  sys_flag,0FFh               ; system block?
  1553.         jne  type5 
  1554.         mov  dx,offset systype
  1555.         jmp  end_type
  1556. type5:
  1557.         call data_name                   ; save the filename if any
  1558.         mov  dx,offset datatype          ; it's a data block 
  1559. end_type:
  1560.         call dostty
  1561.         xor  bx,bx
  1562.  
  1563. owner:
  1564.         mov  dx,offset space1
  1565.         call dostty
  1566.         cmp  sys_flag,0FFh               ; is this THE DOS block?
  1567.         jne  owner1  
  1568.         mov  dx,offset sysmsg            ; assume system block 
  1569.         jmp  end_owner
  1570. owner1:                                  ; 
  1571.         cmp  psp_flag,0FFh               ; if it's a psp and...
  1572.         jne  owner2                      ; 
  1573.         cmp  firstpsp,01h                ; ...not the first PSP...
  1574.         jne  is_tsr                      ; 
  1575.         mov  dx,offset cmndmsg           ; it's command.com
  1576.         jmp  end_owner
  1577. owner2:
  1578.         cmp  env_flag,0FFh               ; is it an environment block?
  1579.         jne  owner3
  1580.         cmp  firstenv,01h                ; is it the DOS environment block?
  1581.         jne  is_tsr
  1582.         mov  dx,offset cmndmsg           ; yes, it belongs to COMMAND.COM
  1583.         jmp  end_owner
  1584. owner3:
  1585.         cmp  mt_flag,0FFh                ; is this block empty?
  1586.         jne  owner4
  1587.         mov  dx,offset mtblkmsg          ; assume that this block is empty
  1588.         jmp  end_owner
  1589. owner4:                                  ; must assume this is a data block
  1590.         mov  dx,offset dataname          ; display last env name
  1591.         jmp  end_owner
  1592. is_tsr:                                  ; this block is a TSR   
  1593.         mov  dx,offset filename
  1594. end_owner:
  1595.         call dostty                      ; 
  1596.         xor  bx,bx
  1597.  
  1598. comments:
  1599.         mov  dx,offset space2
  1600.         call dostty
  1601. comment1:
  1602.         cmp  env_flag,0FFh               ; environment? 
  1603.         jne  comment2 
  1604.         cmp  firstenv,01h                ; first environment? 
  1605.         je   comment4
  1606.         mov  dx,offset envmsg            ; process environment
  1607.         jmp  end_comment
  1608. comment2:
  1609.         cmp  sys_flag,0FFh               ; is this a system owned block?
  1610.         jne  comment3
  1611.         mov  dx,offset drvmsg            ; dev drvs, etc.
  1612.         jmp  end_comment
  1613. comment3:
  1614.         cmp  mt_flag,0FFh                ; is this block empty?
  1615.         jne  comment5
  1616.         mov  dx,offset de_allocmsg       ; assume that this block is empty
  1617.         jmp  end_comment
  1618. comment4:
  1619.         mov  dx,offset mastenv           ; this is the DOS master environment
  1620.         and  firstenv,0h                 ; there can be only one
  1621.         jmp  end_comment
  1622. comment5:
  1623.         cmp  psp_flag,0FFh               ; is this a tsr?
  1624.         jne  comment7
  1625.         cmp  firstpsp,01h                ; first PSP?
  1626.         je   comment6
  1627.         mov  dx,offset tsrmsg            ; TSR
  1628.         jmp  end_comment
  1629. comment6:
  1630.         mov  dx,offset resdmsg           ; resident part of command.com
  1631.         and  firstpsp,0h                 ; there can be only one
  1632.         jmp  end_comment
  1633. comment7:
  1634.         mov  dx,offset datamsg           ; must assume process data
  1635.         jmp  end_comment
  1636. end_comment:
  1637.         call dostty
  1638.         xor  bx,bx
  1639. ;***********************************************************************
  1640. ;* Display the command line arguments for this TSR
  1641. ;***********************************************************************
  1642. args:
  1643.         call chk_args
  1644. ;***********************************************************************
  1645. ;* Find and display any interrupt vectors hooked by this TSR.          *
  1646. ;***********************************************************************
  1647. chk_vec:                                 ; print hooked vectors here
  1648.         mov  dx,word ptr es:[bx+3]       ; get number of paragraphs allocated
  1649.         mov  ax,es                       ; get mcb seg
  1650.         inc  ax                          ; account for length of mcb
  1651.         mov  blk_beg,ax                  ; this is where the blk begins
  1652.         add  ax,dx                       ; add the length of the blk
  1653.         mov  blk_end,ax                  ; this is where the blk ends
  1654.         push es
  1655.         mov  ax,0h
  1656.         mov  es,ax
  1657.         and  vectcnt,0h
  1658.         mov  dx,vectcnt
  1659.         mov  cl,4
  1660.         mov  cnt,0h
  1661. vect_loop:
  1662.         shl  dx,1                        ; multiply the interrupt number...
  1663.         shl  dx,1                        ; ...by 4 to get offset of vector...
  1664.         mov  bx,dx                       ; .....in table.
  1665.         mov  ax,word ptr es:[bx+2]       ; get the vector segment
  1666.         mov  dx,word ptr es:[bx]         ; get the vector offset
  1667.         shr  dx,cl                       ; divide by 16 to get paragraphs
  1668.         add  ax,dx                       ; add them to get seg addr of entry
  1669.         cmp  ax,blk_beg                  ; compare the mcb seg and int seg
  1670.         jnb  chk_end                     ; int seg is greater...chk end seg
  1671.         jmp  not_hooked
  1672. chk_end:
  1673.         cmp  ax,blk_end                  ; compare the ending seg and int seg
  1674.         jna  is_hooked                   ; if int seg less, vector is hooked
  1675.         jmp  not_hooked                  ; ...otherwise it's not.
  1676. is_hooked:
  1677.         mov  ax,vectcnt                  ; print the interrupt number
  1678.         mov  sav_addr,ax                 ; put it where display routine wants
  1679.     mov  cx,1                     ; count of bytes to display
  1680.     lea  bx,[sav_addr]
  1681.         call show_bytes                  
  1682.         mov  dx, offset space1
  1683.         call dostty
  1684.         inc  cnt
  1685.         cmp  cnt,05h
  1686.         jbe  not_hooked                  ; see if we have to wrap the line
  1687.         and  cnt,0h
  1688.     mov  dx,offset newline
  1689.         call dostty
  1690.         call chk_screen
  1691.         mov  dx,offset space12
  1692.         call dostty                      ; align the wrap line
  1693.         mov  dx,offset space12
  1694.         call dostty
  1695.         mov  dx,offset space12
  1696.         call dostty
  1697.         mov  dx,offset space12
  1698.         call dostty
  1699.         mov  dx,offset space11
  1700.         call dostty
  1701.  
  1702. not_hooked:
  1703.         mov  cl,4
  1704.         inc  vectcnt                     ; increment interrupt type number
  1705.         cmp  vectcnt,078h                ; not interested in types > 78h
  1706.         ja   done_vect
  1707.         mov  dx,vectcnt
  1708.         jmp  vect_loop
  1709. done_vect:
  1710.         call chk_screen
  1711.         pop  es
  1712. end_mcb_loop:                              
  1713.     xor  bx,bx                       ; offset will always be zero
  1714.         mov  ax,mcbseg                   ; seg addr of MCB
  1715.         mov  dx,word ptr es:[bx+3]       ; get number of paragraphs allocated
  1716.         add  ax,dx                       ; add paragraphs allocated to seg addr
  1717.         inc  ax                          ; +16 to account for the MCB length
  1718.         mov  es,ax                       ; this is the new seg addr
  1719.         jmp  mcb_loop
  1720.  
  1721. ;***********************************************************************
  1722. ;* This is the MCB for snoop.com                                       *
  1723. ;***********************************************************************
  1724. last_mcb:
  1725.         or   psp_flag,0FFh
  1726.     mov  dx,offset newline         
  1727.         call dostty
  1728.         xor  bx,bx
  1729.         call disp_hex
  1730.         mov  dx, offset space2           
  1731.         call dostty
  1732.         xor  bx,bx
  1733.         mov  ax,word ptr es:[bx+1]       ; get seg addr this MCB allocates for
  1734.         call disp_hex
  1735.         mov  dx, offset space3
  1736.         call dostty
  1737.         xor  bx,bx
  1738.         mov  ax,word ptr es:[bx+3]       ; get number of paragraphs allocated
  1739.         call disp_hex
  1740.         mov  dx, offset space2
  1741.         call dostty
  1742.         mov  dx, offset psptype
  1743.         call dostty
  1744.         mov  dx,offset space1
  1745.         call dostty
  1746.         mov  dx,offset filename
  1747.         call dostty
  1748.         mov  dx,offset space2
  1749.         call dostty
  1750.         mov  dx,offset thismsg           ; assume that this block is free
  1751.         call dostty
  1752.         call chk_args
  1753.     mov  dx,offset newline         
  1754.         call dostty
  1755. ;***********************************************************************
  1756. ;* End of Job.                                                         *
  1757. ;***********************************************************************
  1758. quit:
  1759.     mov  ax,4C00h                 ; Return code for normal completion
  1760.     int  21h             ; return to DOS
  1761. main    endp
  1762. ;
  1763. ;
  1764. ;***********************************************************************
  1765. ;
  1766. ;  Called procedures (Near)
  1767. ;
  1768. ;***********************************************************************
  1769. ;
  1770. ;***********************************************************************
  1771. ;* DOS TTY Write
  1772. ;***********************************************************************
  1773. dostty  proc near
  1774.         push ax
  1775.     mov  ah,09h             ; ah=09h: display string at ds:dx
  1776.     int  21h
  1777.         pop  ax
  1778.     ret
  1779. dostty  endp
  1780.  
  1781. ;***********************************************************************
  1782. ;* DOS Display Single Character
  1783. ;***********************************************************************
  1784.  
  1785. dos_char proc near
  1786.         push ax
  1787.         mov  ah,2                        ; ah=02h: display char in dl
  1788.         int  21h
  1789.         pop  ax
  1790.         ret
  1791. dos_char endp
  1792.  
  1793. ;***********************************************************************
  1794. ;* Prints a colon between seg and offset addresses
  1795. ;***********************************************************************
  1796. split    proc near
  1797.     push ax
  1798.     mov  al,colon
  1799.     call show_ascii
  1800.     pop  ax
  1801.     ret
  1802. split    endp
  1803.  
  1804. ;***********************************************************************
  1805. ;* Prints a single space
  1806. ;***********************************************************************
  1807. space    proc near
  1808.     push ax
  1809.     mov  al,blank
  1810.     call show_ascii
  1811.     pop  ax
  1812.     ret
  1813. space    endp
  1814.  
  1815. ;***********************************************************************
  1816. ;* Converts Hex numbers for display.
  1817. ;***********************************************************************
  1818. show_bytes proc    near
  1819.     push ax
  1820.     push bx
  1821.     push cx
  1822. sbs_loop:
  1823.     mov  al,[bx]
  1824.     call show_byte
  1825.     inc  bx
  1826.     loop sbs_loop
  1827.     pop  cx
  1828.     pop  bx
  1829.     pop  ax
  1830.     ret
  1831. show_bytes endp
  1832.  
  1833. ;***********************************************************************
  1834. ;* Convert the hex character.
  1835. ;***********************************************************************
  1836. show_byte proc near
  1837.     pushf
  1838.     push cx
  1839.     push ax
  1840.     mov  cl,4h    ;shift rt 4 bits
  1841.     shr  al,cl    ;to isolate m.s. nybble
  1842.     call test    ;display hex contents
  1843.     pop  ax            ;retrieve al
  1844.     and  al,0fh    ;isolate l.s. nybble
  1845.     call test    ;display hex contents
  1846.     pop  cx
  1847.     popf
  1848.     ret
  1849. show_byte endp
  1850.  
  1851. ;***********************************************************************
  1852. ;* Determines if hex digit is a letter.
  1853. ;***********************************************************************
  1854. test    proc near
  1855.     cmp  al,9h    ;is nybble letter?
  1856.     ja   letter    ;if so convert to letter
  1857.     or   al,30h    ;if not add '30' code
  1858.     jmp  display
  1859. letter:
  1860.     sub  al,9h    ;reduce letter nybble by 9
  1861.     or   al,40h    ;add '40' code
  1862. display:
  1863.     call show_ascii
  1864.     ret    
  1865. test    endp
  1866.  
  1867. ;***********************************************************************
  1868. ;* Displays ASCII characters.
  1869. ;***********************************************************************
  1870. show_ascii    proc     near
  1871.     push ax
  1872.     push dx
  1873.     mov  dl,al
  1874.     mov  ah,02h            ;ah=02: display char in dl         
  1875.     int  21h
  1876.         pop  dx
  1877.     pop  ax
  1878.     ret
  1879. show_ascii endp
  1880. ;
  1881. ;*************************************************************************
  1882. ;* dec16out - Routine to convert internal 16 bit binary to ASCII decimal *
  1883. ;*************************************************************************
  1884. dec16out proc near
  1885. dec16out0:
  1886.     push ds
  1887.     push di
  1888.     push dx
  1889.     push cx
  1890.     push ax
  1891.     mov ax,cs
  1892.     mov ds,ax
  1893.                                          ; a binary number is in dx
  1894.                                          ; put the digits in a temporary buffer
  1895.     mov cx,0
  1896.     mov di, offset cs:tbuff          ; point to buffer
  1897. dec16out1:
  1898.     push cx
  1899.     mov  ax,dx                 ; ax has numerator
  1900.     mov  dx,0        
  1901.     mov  cx,10d                 ; divisor of 10
  1902.     div  cx
  1903.     xchg ax,dx                 ; get quotient
  1904.     add  al,30h
  1905.     mov  [di],al                 ; put in buffer
  1906.     inc  di                     ; point to next byte
  1907.     pop  cx
  1908.     inc  cx                     ; count the digit
  1909.     cmp  dx,0                 ; done?
  1910.     jnz  dec16out1
  1911.                                          ; dump the buffer out
  1912. dec16out2:
  1913.     dec  di                     ; back up through the buffer
  1914.     mov  al,[di]
  1915.     call stdout
  1916.     loop dec16out2
  1917.     pop  ax
  1918.     pop  cx
  1919.     pop  dx
  1920.     pop  di
  1921.     pop  ds
  1922.     ret
  1923. dec16out endp
  1924. ;
  1925. ;***********************************************************************
  1926. ;* Display device driver names so embedded "$" while display.
  1927. ;***********************************************************************
  1928. disp_dev_drv proc near
  1929.         push bx
  1930.         push si                          ; save the count
  1931.         xor  si,si
  1932.         mov  bx,dx
  1933. disp_drv_loop:
  1934.         cmp  byte ptr ds:[bx+si],0FFh    ; the field termination character
  1935.         je   end_drv_loop
  1936.         mov  al,byte ptr ds:[bx+si]      ; set it up for stdout
  1937.         call stdout
  1938.         inc  si
  1939.         cmp  si,0Dh                      ; paranoia: are we done yet?
  1940.         je   end_drv_loop
  1941.         jmp  disp_drv_loop
  1942. end_drv_loop:
  1943.         pop  si
  1944.         pop  bx
  1945.         ret
  1946. disp_dev_drv endp
  1947. ;
  1948. ;***********************************************************************
  1949. ;* Sends a character to the std ouput device.
  1950. ;***********************************************************************
  1951. stdout  proc near
  1952.     push dx
  1953.     mov  dl,al        ;in dl for DOS call
  1954.     mov  ah,2        ;send character to std output
  1955.     int  21h
  1956.     pop  dx
  1957.     ret
  1958. stdout  endp                
  1959. ;***********************************************************************
  1960. ;* Finds EGA Copyright String.
  1961. ;***********************************************************************
  1962. ega_copy proc near
  1963.         cmp  ps2_flag,0h                 ; PS/2 series has onboard VGA
  1964.         je   not_vga                     ; and therefore no EGA copyright
  1965.         jmp  vga_exit
  1966. not_vga:
  1967.     mov  dx,offset newline         
  1968.         call dostty
  1969.     mov  dx,offset indent          
  1970.         call dostty
  1971.     mov  dx,offset egacopy         ; copyright header
  1972.         call dostty
  1973.         push es
  1974.         push ds
  1975.         push ds
  1976.         pop  es                          ; destination string address in es:di
  1977.         mov  ax,0C000h                   ; source string address in ds:si
  1978.         mov  ds,ax                       ; ...location of IBM EGA copyright
  1979.         mov  ax,05h                      ; 
  1980.         mov  cx,11h                      ; count of words in copyright
  1981.         mov  bx,cx                       ;
  1982.         shl  bx,1                        ; multiply by 2 then subtract 1...
  1983.         dec  bx                          ; ... to get offset of...
  1984.         mov  si,ax                       ; terminator character in dest string
  1985.         mov  di,offset es:tbuff
  1986.         rep  movsw
  1987.         pop  ds
  1988.         pop  es
  1989.         mov  byte ptr tbuff+[bx],'$'    ; insert terminator
  1990.         mov  bx, offset tbuff
  1991. scan_copy:
  1992.         cmp  byte ptr[bx],'$'           ; are we done?
  1993.         je   done_copy                  ; go display it
  1994.         cmp  byte ptr[bx],' '           ; less than a space?
  1995.         jb   mask_it                    ;
  1996.         cmp  byte ptr[bx],'~'           ; greater than a tilde
  1997.         jna  inc_bx                     ; if not it's printable
  1998.         
  1999. mask_it:
  2000.         mov  byte ptr[bx],20h           ; make nonsense characters a space
  2001. inc_bx:
  2002.         inc  bx                         ; increment the address
  2003.         jmp  scan_copy                  ; go do it again
  2004. done_copy:
  2005.         mov  dx,offset tbuff            ; 
  2006.         call dostty
  2007.         push es
  2008.         push ds
  2009.         push ds
  2010.         pop  es                          ; destination string address in es:di
  2011.     mov  dx,offset newline         
  2012.         call dostty
  2013.     mov  dx,offset indent          
  2014.         call dostty
  2015.     mov  dx,offset egadate         ; date header
  2016.         call dostty
  2017.         mov  ax,0C000h                   ; source string address in ds:si
  2018.         mov  ds,ax
  2019.         mov  ax,26h                      ; offset of EGA rom release date
  2020.         mov  si,ax
  2021.         mov  di,offset es:tbuff
  2022.         mov  cx,04h                      ; count of words
  2023.         rep  movsw
  2024.         pop  ds
  2025.         pop  es
  2026.         mov  byte ptr tbuff[07h],'$'
  2027.         mov  dx,offset tbuff             ; 
  2028.         call dostty
  2029. vga_exit:
  2030.         ret
  2031. ega_copy endp
  2032. ;***********************************************************************
  2033. ;* Division Routine.
  2034. ;***********************************************************************
  2035. divide  proc near
  2036.         mov  ax,bx
  2037.         xor  dx,dx
  2038.         div  cx
  2039.         mov  bx,dx
  2040.         mov  dl,al
  2041.         cmp  al,0
  2042.         jz   chk_flag
  2043.         or   display_flag,al
  2044. chk_flag:
  2045.         cmp  display_flag,0
  2046.         ja   display_it
  2047.         ret
  2048. display_it:
  2049.         add  dl,30h
  2050.         call dos_char
  2051.         ret
  2052. divide  endp
  2053. ;***********************************************************************
  2054. ; Pause the scrolling display.
  2055. ;***********************************************************************
  2056. pause   proc near
  2057.         cmp  byte ptr pse_flag,0h        ; are we to pause the display?
  2058.         jne  no_pause                    ; if pause is zero we will
  2059.         cmp  byte ptr optcnt,0h          ; last option?
  2060.         jbe  no_pause                    ; if so don't pause
  2061.         push dx
  2062.     mov  dx,offset msg7         ; 
  2063.         call dostty
  2064.     mov  ah,get_key                  ; function number
  2065.     int  16h                         ; ascii code for key pressed in ah
  2066.         pop  dx
  2067. no_pause:
  2068.         ret                              ; yes - return to caller
  2069. pause   endp
  2070.  
  2071. ;***********************************************************************
  2072. ;* Get a block device driver's name into a buffer for display.
  2073. ;***********************************************************************
  2074. blk_name proc near
  2075.         mov  al,byte ptr es:[bx+0Ah]     ; first byte is number of units
  2076.         add  al,30h                      ; make it ascii
  2077.         mov  ah,20h                      ; add a space
  2078.         mov  word ptr sav_name,ax        ; store it
  2079.         mov  ax,es:[bx+12h]              ; remainder of name...
  2080.         mov  word ptr sav_name+2,ax
  2081.         mov  ax,es:[bx+14h]              ; ...if any, follows units...
  2082.         mov  word ptr sav_name+4,ax
  2083.         mov  ax,es:[bx+16h]              ; ...and may include...
  2084.         mov  word ptr sav_name+6,ax
  2085.         mov  ax,es:[bx+18h]              ; ....some garbage characters...
  2086.         mov  word ptr sav_name+8,ax
  2087.         mov  ax,es:[bx+1Ah]              ; ...whic is unavoidable...
  2088.         mov  word ptr sav_name+10,ax
  2089.         mov  ax,es:[bx+1Ch]              ; ...because I want to see the name.
  2090.         mov  word ptr sav_name+12,ax
  2091.         mov  byte ptr sav_name+13,0FFh   ; the field termination character
  2092.         ret
  2093. blk_name endp
  2094. ;
  2095.  
  2096. ;***********************************************************************
  2097. ;* Search for Task Name in Command Line in Environment.
  2098. ;***********************************************************************
  2099. get_name proc near
  2100.         cmp  dos_vers+1,02h              ; name not available in DOS 2.x
  2101.         ja   vers_ok
  2102.         mov  arg_cnt,0h                  ; ignore switches
  2103.         jmp  quick_x                     ; display spaces for owner name
  2104. vers_ok:
  2105.         mov  dx,0000h
  2106.         mov  bx,10h
  2107.         mov  cx,532h                     ; env can't be longer than this
  2108. look_for:
  2109.         dec  cx
  2110.         cmp  cx,0h                       ; have we checked 1,330 chars?
  2111.         jne  not_1330                    ; no, continue the search
  2112.         mov  arg_cnt,0h                  ; yes, ignore switches
  2113.         jmp  quick_x                     ; display spaces for owner name
  2114. not_1330:
  2115.         inc  bx                          ; a byte at a time.....
  2116.         cmp  word ptr es:[bx],dx         ; ...look for back to back ascii nuls
  2117.         jne  look_for
  2118.         add  bx,2                        ; found them...
  2119.         mov  ax,word ptr es:[bx]         ; ... get count of command line args
  2120.         mov  arg_cnt,ax
  2121.         add  bx,3
  2122.         cmp  byte ptr es:[bx],':'         ; ...looking for :\
  2123.         je   not_netware
  2124.         mov  arg_cnt,0h                  ; ignore switches
  2125.         jmp  quick_x                     ; display spaces for owner name
  2126. not_netware:
  2127.         inc  bx                          ; step over ":"
  2128.         cmp  byte ptr es:[bx],5Ch        ; ...looking for "\" path delimiter
  2129.         je   not_novelle
  2130.         cmp  byte ptr es:[bx],2Fh        ; ...looking for "/" path delimiter
  2131.         je   not_novelle                 ; Novelle Netware does not use either
  2132.         mov  arg_cnt,0h                  ; won't find task name so ignore
  2133.         jmp  quick_x                     ; display spaces for owner name
  2134. not_novelle:
  2135.         inc  bx                          ; step over the "\" or "/"
  2136.         mov  di,offset filename
  2137.         mov  si,bx                       ; si is offset of beginning of name
  2138.         xor  cx,cx
  2139. mov_name:
  2140.         cmp  byte ptr es:[si],5Ch        ; looking for embedded '\' in path
  2141.         je   restart_scan
  2142.         cmp  byte ptr es:[si],2Fh        ; looking for embedded '/' in path
  2143.         jne  no_path
  2144. restart_scan:
  2145.         mov  di,offset filename          ; reset dest offset to beginning
  2146.         inc  si                          ; bump si past '\' or '/'
  2147.         xor  cx,cx
  2148.         jmp  mov_name                    ; go back and start again
  2149. no_path:
  2150.         cmp  byte ptr es:[si],2Eh        ; looking for '.' to exclude extension
  2151.         je   end_name
  2152.         cmp  cx,8h                       ; filename is 8 chars long max
  2153.         je   fini
  2154.         mov  al,byte ptr es:[si]
  2155.         mov  byte ptr ds:[di],al
  2156.         inc  si
  2157.         inc  di
  2158.         inc  cx
  2159.         jmp  mov_name
  2160. end_name:
  2161.         cmp  cx,8h                       ; filename is 8 chars long
  2162.         jnb  fini
  2163.         mov  byte ptr ds:[di],20h
  2164.         inc  di
  2165.         inc  cx
  2166.         jmp  end_name
  2167. fini:
  2168.         mov  byte ptr ds:[di],'$'
  2169. quick_x:
  2170.     xor  bx,bx                       ; offset will always be zero
  2171.         ret
  2172. get_name endp
  2173. ;***********************************************************************
  2174. ;* Save the filename for data blocks
  2175. ;***********************************************************************
  2176. ;
  2177. data_name proc near
  2178.         cmp  byte ptr filename,20h       ; will be a space first time around
  2179.         jne  not_first
  2180.     call get_owner             ; find the owning task name
  2181. not_first:
  2182.         cmp  data_flag,0FFh              ; if set, name is already in place
  2183.         je   data_exit                   ; exit if it is
  2184.         push es                          ; save MCB seg addr
  2185.         push ds                          ; establish addressibility
  2186.         pop  es                          ; destination string address in es:di
  2187.         mov  ax,offset filename          ; offset of filename 
  2188.         mov  si,ax                       ; set up source index
  2189.         mov  di,offset es:dataname       ; set up destination index
  2190.         mov  cx,04h                      ; count of words (8 bytes)
  2191.         rep  movsw                       ; do the move
  2192.         mov  byte ptr dataname[08h],'$'  ; string terminator for DOS
  2193.         or   data_flag,0FFh              ; set it for next time
  2194.         pop  es                          ; restore MCB seg addr
  2195. data_exit:
  2196.         ret
  2197. data_name endp
  2198. ;
  2199. ;***********************************************************************
  2200. ;* Get name of task that owns this data block.
  2201. ;***********************************************************************
  2202. get_owner proc near
  2203.     push es
  2204.     push bx
  2205.     xor  bx,bx
  2206.     mov  ax,word ptr es:[bx+1]      ; get seg addr of blk this MCB controls
  2207.     mov  es,ax                       ; es now points to PSP of owner
  2208.     mov  ax,word ptr es:[bx+2Ch]     ; get seg addr of environment
  2209.     mov  es,ax                       ; es now points to Env of owner
  2210.     call get_name                    ; call the normal get name routine    
  2211.     pop  bx
  2212.     pop  es
  2213.     ret
  2214. get_owner endp
  2215. ;
  2216. ;***********************************************************************
  2217. ;* Display Hex Numbers.
  2218. ;***********************************************************************
  2219. disp_hex proc near
  2220.         push bx
  2221.         xchg ah,al                       ; get it turned around
  2222.         mov  sav_addr,ax                 ; 
  2223.     mov  cx,2                     ; count of bytes to display
  2224.     lea  bx,[sav_addr]
  2225.         call show_bytes
  2226.         pop  bx
  2227.         ret
  2228. disp_hex endp
  2229. ;
  2230. ;***********************************************************************
  2231. ;*  Check for command line switches in the TSR's PSP.                  *
  2232. ;***********************************************************************
  2233. chk_args proc near
  2234.         push bx
  2235.         cmp  psp_flag,0FFh               ; is this a PSP?
  2236.         jne  no_args
  2237.         cmp  arg_cnt,0h                  ; any command line switches?
  2238.         je   no_args
  2239.         mov  bx,90h                      ; offset of count (including MCB)
  2240.         mov  ax,es:[bx]                  ; PSP arg cnt
  2241.         cmp  ax,0h                       ; any args?
  2242.         je   end_args
  2243.         inc  bx                          ; point to tail
  2244. arg_loop:
  2245.         cmp  byte ptr es:[bx],0Dh        ; CR ends tail
  2246.         je   end_args
  2247.         mov  al,es:[bx]
  2248.         call stdout
  2249.         inc  bx                          ; bump offset
  2250.         cmp  bx,9Bh                      ; only room for 9 characters
  2251.         jb   arg_loop
  2252. end_args:
  2253.         sub  bx,91h                      ; get number of spaces to print
  2254.         cmp  bx,0h
  2255.         jbe  no_args                     ; if negative, no args        
  2256.         mov  cx,0Ch
  2257.         sub  cx,bx
  2258. fill_loop:
  2259.         mov  al,20h
  2260.         call stdout
  2261.         loop fill_loop
  2262.         jmp  exit_args
  2263. no_args:
  2264.         mov  dx,offset space12           ; change # of spaces for args print
  2265.         call dostty                      ; 
  2266. exit_args:
  2267.         pop  bx
  2268.         ret
  2269. chk_args endp
  2270. ;***********************************************************************
  2271. ;* See if 80286 or 80386 CPU using Intel approved method
  2272. ;***********************************************************************
  2273. chk_cpu proc near
  2274.         push ax
  2275.         mov  cpu_flag,0h                 ; clear it
  2276.         pushf                            ; save original flags
  2277.         pushf                            ; make extra copy of flags register..
  2278.         pop  ax                          ; bits 12-14 can be set on a 386 only
  2279.         or   ax,0111000000000000b        ; turn on bits 12-14
  2280.         push ax                          ; 
  2281.         popf                             ; pop this value back into flags reg
  2282.         pushf                            ; 
  2283.         pop  ax                          ; look at results
  2284.         and  ax,0111000000000000b        ; see if bits 12-14 are set
  2285.         jnz  is_32_bit                   ; if they're set, it's a 386 cpu        
  2286. is_16_bit:
  2287.         popf                             ; restore flags
  2288.     or   byte ptr cs:cpu_flag,02h    ; indicate 286 cpu
  2289.         jmp  cpu_exit
  2290. is_32_bit:
  2291.         popf                             ; restore flags
  2292.     or   byte ptr cs:cpu_flag,03h    ; indicate 386 cpu
  2293.         jmp  cpu_exit
  2294. cpu_exit:
  2295.         pop  ax
  2296.         ret
  2297. chk_cpu endp
  2298. ;
  2299. ;***********************************************************************
  2300. ;* Check to see if this is an IBM Personal System/2 Machine    *
  2301. ;***********************************************************************
  2302. ; Model Id Byte values and meanings:
  2303. ;
  2304. ; IBM Personal System/2 Model 30
  2305. ; at address F000:FFFE FA 
  2306. ;
  2307. ; IBM Personal System/2 Model 50
  2308. ; at address E000:7AF9 FC 04 <====Rom Revision Level 4.
  2309. ;
  2310. ; IBM Personal System/2 Model 60
  2311. ; at address E000:7B03 FC 05 <====Rom Revision Level 5.
  2312. ;
  2313. ; IBM Personal System/2 Model 80
  2314. ; at address E000:xxxx F8 00           F8 is an educated guess
  2315. ;
  2316. chk_ps2 proc near
  2317.         and  ps2_flag,0h
  2318.         cmp  word ptr es:[bx+2],04FCh
  2319.         je   model_50
  2320.         cmp  word ptr es:[bx+2],05FCh
  2321.         je   model_60
  2322.         cmp  byte ptr es:[bx+2],0F8h
  2323.         je   need_386
  2324.         jmp  unkn_model
  2325. need_386:
  2326.         call chk_cpu
  2327.     cmp  byte ptr cs:cpu_flag,03h    ; is it a 386 cpu?
  2328.         je   model_80
  2329.         jmp  unkn_model                  ; it's an 80286, 8088, or 8086 
  2330. model_50:
  2331.     or   ps2_flag,50h
  2332.     mov  dx,offset msg1F
  2333.         call dostty
  2334.         jmp  end_ps2
  2335. model_60:
  2336.     or   ps2_flag,60h
  2337.     mov  dx,offset msg1G
  2338.         call dostty
  2339.         jmp  end_ps2
  2340. model_80:
  2341.     or   ps2_flag,80h
  2342.     mov  dx,offset msg1H
  2343.         call dostty
  2344.         jmp  end_ps2
  2345. unkn_model:                              ; probably a PC Convertible
  2346. end_ps2:
  2347.         ret                    
  2348. chk_ps2 endp
  2349. ;
  2350. ;***********************************************************************
  2351. ;* chk_mod30 - Check if this is a PS/2 Model 30.
  2352. ;***********************************************************************
  2353.  
  2354. chk_mod30 proc near
  2355.     cmp  al,0FAh                  ; PS/2 Model 30?
  2356.         je   model_30
  2357.         jmp  end_30
  2358. model_30:
  2359.     or   ps2_flag,30h
  2360.     mov  dx,offset msg1E
  2361.         call dostty
  2362. end_30:
  2363.         ret
  2364. chk_mod30 endp
  2365.  
  2366. ;
  2367. ;***********************************************************************
  2368. ;* chk_switch - Check command line switches for options requested.     *                           *
  2369. ;***********************************************************************
  2370. chk_switch proc near
  2371.         mov  cl,ds:[0080h]               ; command line arg count in PSP
  2372.         cmp  cl,0h                       ; any args?
  2373.         ja   swt_set
  2374.         jmp  end_swt
  2375. swt_set:
  2376.         mov  bx,80h                      ; offset-1 of command tail in PSP
  2377. swt_char:
  2378.         inc  bx
  2379.         cmp  byte ptr ds:[bx],0Dh       ; CR ends command tail
  2380.         jne  more_swt
  2381.         jmp  end_swt
  2382. more_swt:
  2383.         cmp  byte ptr ds:[bx],'/'
  2384.         je   fnd_swt
  2385.         cmp  byte ptr ds:[bx],'\'
  2386.         je   fnd_swt
  2387.         cmp  byte ptr ds:[bx],' '
  2388.         je   fnd_swt
  2389.         cmp  byte ptr ds:[bx],'-'
  2390.         je   fnd_swt
  2391.         jmp  swt_char
  2392. fnd_swt:
  2393.         inc  bx
  2394.         or   byte ptr ds:[bx],20h
  2395.         cmp  byte ptr ds:[bx],'n'
  2396.         jne  chk_equ
  2397.         or   pse_flag,0FFh
  2398.         and  byte ptr one,0h             ; value to add to the line counter
  2399.         jmp  swt_char
  2400. chk_equ:
  2401.         cmp  byte ptr ds:[bx],'e'
  2402.         jne  chk_inv
  2403.         or   equ_flag,0FFh
  2404.         inc  optcnt
  2405.         jmp  swt_char
  2406. chk_inv:
  2407.         cmp  byte ptr ds:[bx],'i'
  2408.         jne  chk_drv
  2409.         or   inv_flag,0FFh
  2410.         inc  optcnt
  2411.         jmp  swt_char
  2412. chk_drv:
  2413.         cmp  byte ptr ds:[bx],'d'
  2414.         jne  chk_mcb
  2415.         or   drv_flag,0FFh
  2416.         inc  optcnt
  2417.         jmp  swt_char
  2418. chk_mcb:
  2419.         cmp  byte ptr ds:[bx],'m'
  2420.         jne  all_chk
  2421.         or   mem_flag,0FFh
  2422.         inc  optcnt
  2423.         jmp  swt_char
  2424. all_chk:
  2425.         cmp  byte ptr ds:[bx],'a'
  2426.         jne  klone_chk
  2427.         or   equ_flag,0FFh
  2428.         or   inv_flag,0FFh
  2429.         or   drv_flag,0FFh
  2430.         or   mem_flag,0FFh
  2431.         or   argc,0FFh
  2432.         jmp  swt_char
  2433. klone_chk:                               ; option for MS-DOS boxes
  2434.         cmp  byte ptr ds:[bx],'x'        ; which are not IBM ROM...
  2435.         jne  last_chk
  2436.         and  equ_flag,0h                 ; ... BIOS compatible. 
  2437.         or   inv_flag,0FFh
  2438.         or   drv_flag,0FFh
  2439.         or   mem_flag,0FFh
  2440.         or   argc,0FFh
  2441.         jmp  swt_char
  2442. last_chk:
  2443.         dec  bx
  2444.         jmp  swt_char
  2445. end_swt:
  2446.         cmp  argc,0FFh
  2447.         jne  not_all
  2448.         mov  optcnt,4
  2449. not_all:
  2450.         cmp  optcnt,1                    ; must specify one switch at least
  2451.         jnb  lv_swt
  2452.         mov  dx,offset usemsg
  2453.         call dostty
  2454.     mov  ax,4C01h                 ; Return code for abnormal completion
  2455.     int  21h             ; return to DOS
  2456. lv_swt:
  2457.         ret
  2458. chk_switch endp
  2459. ;
  2460. ;***********************************************************************
  2461. ;* Check the switch char for path names - is it "/" or "\"?
  2462. ;***********************************************************************
  2463. switch_char proc near
  2464.         mov  ax,3700h                    ; request switchar be returned in dl
  2465.         int  21h
  2466.         cmp  dl,5CH                      ; are they using "\" for switches?
  2467.         jne  not_unix_lover              ; no, "/" for switches, "\" for paths
  2468.         cmp  dl,2FH                      ; are they using "/" for switches?
  2469.         jne  func_not_working            ; if no, the function is not working
  2470.         mov  switchar,5Ch                ; change it around for unix lovers
  2471.         mov  pathchar,2Fh                ; least they be troubled... :-)
  2472.         jmp  func_works
  2473. not_unix_lover:
  2474.         cmp  dl,2FH                      ; are they using "/" for switches?
  2475.         je   func_works                  ; the undocumented function works
  2476. func_not_working:
  2477.         mov  al,0FFh                     ; if no, the function is not working
  2478.                                          ; leave defaults in place, signal err
  2479. func_works:
  2480.         ret
  2481. switch_char endp
  2482. ;
  2483. ;***********************************************************************
  2484. ;* Check to see if screen is full during MCB display.
  2485. ;***********************************************************************
  2486. chk_screen proc near
  2487.         push ax
  2488.         push dx
  2489.         xor  ax,ax
  2490.         mov  al,byte ptr linecnt
  2491.         add  al,one                      ; will be 0 if pause, 1 if not
  2492.         cmp  al,14h                      ; 20 lines per screen
  2493.         jb   not_full
  2494.     mov  dx,offset newline
  2495.         call dostty
  2496.     mov  dx,offset msg7         ; press any key message
  2497.         call dostty
  2498.     mov  ah,get_key                  ; function number (0h or 10h)
  2499.     int  16h                         ; ascii code for key pressed in ah
  2500.         xor  al,al
  2501. not_full:
  2502.         mov  byte ptr linecnt,al         ; store the updated counter
  2503.         pop  dx
  2504.         pop  ax
  2505.         ret
  2506. chk_screen endp
  2507. ;
  2508. cseg    ends
  2509.     end  begin
  2510. ;*****************************************************************************
  2511. ;* End Of Source Code.
  2512. ;*****************************************************************************
  2513.